From 54409423f767d8b1cf30cb7d0efca6b4ca138823 Mon Sep 17 00:00:00 2001
From: Ethan Morgan <ethan@gweithio.com>
Date: Sat, 14 Feb 2026 16:44:06 +0000
Subject: move to own git server

---
 vcpkg/scripts/toolchains/openbsd.cmake | 64 ++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 vcpkg/scripts/toolchains/openbsd.cmake

(limited to 'vcpkg/scripts/toolchains/openbsd.cmake')

diff --git a/vcpkg/scripts/toolchains/openbsd.cmake b/vcpkg/scripts/toolchains/openbsd.cmake
new file mode 100644
index 0000000..f500bab
--- /dev/null
+++ b/vcpkg/scripts/toolchains/openbsd.cmake
@@ -0,0 +1,64 @@
+if(NOT _VCPKG_OPENBSD_TOOLCHAIN)
+    set(_VCPKG_OPENBSD_TOOLCHAIN 1)
+
+    if(POLICY CMP0056)
+        cmake_policy(SET CMP0056 NEW)
+    endif()
+    if(POLICY CMP0066)
+        cmake_policy(SET CMP0066 NEW)
+    endif()
+    if(POLICY CMP0067)
+        cmake_policy(SET CMP0067 NEW)
+    endif()
+    if(POLICY CMP0137)
+        cmake_policy(SET CMP0137 NEW)
+    endif()
+    list(APPEND CMAKE_TRY_COMPILE_PLATFORM_VARIABLES
+        VCPKG_CRT_LINKAGE VCPKG_TARGET_ARCHITECTURE
+        VCPKG_C_FLAGS VCPKG_CXX_FLAGS
+        VCPKG_C_FLAGS_DEBUG VCPKG_CXX_FLAGS_DEBUG
+        VCPKG_C_FLAGS_RELEASE VCPKG_CXX_FLAGS_RELEASE
+        VCPKG_LINKER_FLAGS VCPKG_LINKER_FLAGS_RELEASE VCPKG_LINKER_FLAGS_DEBUG
+    )
+
+    if(CMAKE_HOST_SYSTEM_NAME STREQUAL "OpenBSD")
+        set(CMAKE_CROSSCOMPILING OFF CACHE BOOL "")
+    endif()
+    set(CMAKE_SYSTEM_NAME OpenBSD CACHE STRING "")
+
+    if(NOT DEFINED CMAKE_SYSTEM_PROCESSOR)
+        if(VCPKG_TARGET_ARCHITECTURE STREQUAL "x64")
+           set(CMAKE_SYSTEM_PROCESSOR x86_64 CACHE STRING "")
+        elseif(VCPKG_TARGET_ARCHITECTURE STREQUAL "x86")
+           set(CMAKE_SYSTEM_PROCESSOR x86 CACHE STRING "")
+        elseif(VCPKG_TARGET_ARCHITECTURE STREQUAL "arm64")
+           set(CMAKE_SYSTEM_PROCESSOR arm64 CACHE STRING "")
+        else()
+           set(CMAKE_SYSTEM_PROCESSOR "${CMAKE_HOST_SYSTEM_PROCESSOR}" CACHE STRING "")
+        endif()
+    endif()
+
+    if(NOT DEFINED CMAKE_CXX_COMPILER)
+        set(CMAKE_CXX_COMPILER "/usr/bin/clang++")
+    endif()
+    if(NOT DEFINED CMAKE_C_COMPILER)
+        set(CMAKE_C_COMPILER "/usr/bin/clang")
+    endif()
+
+    string(APPEND CMAKE_C_FLAGS_INIT " -fPIC ${VCPKG_C_FLAGS} ")
+    string(APPEND CMAKE_CXX_FLAGS_INIT " -fPIC ${VCPKG_CXX_FLAGS} ")
+    string(APPEND CMAKE_C_FLAGS_DEBUG_INIT " ${VCPKG_C_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_CXX_FLAGS_DEBUG_INIT " ${VCPKG_CXX_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_C_FLAGS_RELEASE_INIT " ${VCPKG_C_FLAGS_RELEASE} ")
+    string(APPEND CMAKE_CXX_FLAGS_RELEASE_INIT " ${VCPKG_CXX_FLAGS_RELEASE} ")
+
+    string(APPEND CMAKE_MODULE_LINKER_FLAGS_INIT " ${VCPKG_LINKER_FLAGS} ")
+    string(APPEND CMAKE_SHARED_LINKER_FLAGS_INIT " ${VCPKG_LINKER_FLAGS} ")
+    string(APPEND CMAKE_EXE_LINKER_FLAGS_INIT " ${VCPKG_LINKER_FLAGS} ")
+    string(APPEND CMAKE_MODULE_LINKER_FLAGS_DEBUG_INIT " ${VCPKG_LINKER_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_SHARED_LINKER_FLAGS_DEBUG_INIT " ${VCPKG_LINKER_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_EXE_LINKER_FLAGS_DEBUG_INIT " ${VCPKG_LINKER_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_MODULE_LINKER_FLAGS_RELEASE_INIT " ${VCPKG_LINKER_FLAGS_RELEASE} ")
+    string(APPEND CMAKE_SHARED_LINKER_FLAGS_RELEASE_INIT " ${VCPKG_LINKER_FLAGS_RELEASE} ")
+    string(APPEND CMAKE_EXE_LINKER_FLAGS_RELEASE_INIT " ${VCPKG_LINKER_FLAGS_RELEASE} ")
+endif(NOT _VCPKG_OPENBSD_TOOLCHAIN)
-- 
cgit v1.2.3