move to own git serverHEADmaster

5 files changed, 151 insertions, 0 deletions

diff --git a/vcpkg/ports/cudnn/FindCUDNN.cmake b/vcpkg/ports/cudnn/FindCUDNN.cmake
new file mode 100644
index 0000000..c09e9d9
--- /dev/null
+++ b/vcpkg/ports/cudnn/FindCUDNN.cmake
@@ -0,0 +1,105 @@
+# Distributed under the OSI-approved BSD 3-Clause License.
+
+#.rst:
+# FindCUDNN
+# --------
+#
+# Result Variables
+# ^^^^^^^^^^^^^^^^
+#
+# This module will set the following variables in your project::
+#
+#  ``CUDNN_FOUND``
+#    True if CUDNN found on the local system
+#
+#  ``CUDNN_INCLUDE_DIRS``
+#    Location of CUDNN header files.
+#
+#  ``CUDNN_LIBRARIES``
+#    The CUDNN libraries.
+#
+#  ``CuDNN::CuDNN``
+#    The CUDNN target
+#
+
+include(FindPackageHandleStandardArgs)
+file(GLOB CUDNN_VERSION_DIRS
+  LIST_DIRECTORIES true
+  "$ENV{CUDA_PATH}/../../../NVIDIA/CUDNN/v[1-9]*.[0-9]*"
+)
+find_path(CUDNN_INCLUDE_DIR NAMES cudnn.h cudnn_v8.h cudnn_v7.h
+  HINTS ${CUDA_TOOLKIT_ROOT} $ENV{CUDA_PATH} $ENV{CUDA_TOOLKIT_ROOT_DIR} $ENV{cudnn} $ENV{CUDNN} $ENV{CUDNN_ROOT_DIR} ${CUDNN_VERSION_DIRS} /usr/include /usr/include/x86_64-linux-gnu/ /usr/include/aarch64-linux-gnu/
+  PATH_SUFFIXES cuda/include include include/11.8 include/12.0 include/12.1 include/12.2 include/12.3 include/12.4 include/12.5 include/12.6 include/12.7 include/12.8 include/12.9)
+find_library(CUDNN_LIBRARY NAMES cudnn cudnn8 cudnn7
+  HINTS ${CUDA_TOOLKIT_ROOT} $ENV{CUDA_PATH} $ENV{CUDA_TOOLKIT_ROOT_DIR} $ENV{cudnn} $ENV{CUDNN} $ENV{CUDNN_ROOT_DIR} ${CUDNN_VERSION_DIRS} /usr/lib/x86_64-linux-gnu/ /usr/lib/aarch64-linux-gnu/ /usr/
+  PATH_SUFFIXES lib lib64 cuda/lib cuda/lib64 lib/x64 cuda/lib/x64 lib/11.8/x64 lib/12.0/x64 lib/12.1/x64 lib/12.2/x64 lib/12.3/x64 lib/12.4/x64 lib/12.5/x64 lib/12.6/x64 lib/12.7/x64 lib/12.8/x64 lib/12.9/x64)
+
+if(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn.h")
+  file(READ ${CUDNN_INCLUDE_DIR}/cudnn.h CUDNN_HEADER_CONTENTS)
+elseif(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_v8.h")
+  file(READ ${CUDNN_INCLUDE_DIR}/cudnn_v8.h CUDNN_HEADER_CONTENTS)
+elseif(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_v7.h")
+  file(READ ${CUDNN_INCLUDE_DIR}/cudnn_v7.h CUDNN_HEADER_CONTENTS)
+endif()
+if(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_version.h")
+  file(READ "${CUDNN_INCLUDE_DIR}/cudnn_version.h" CUDNN_VERSION_H_CONTENTS)
+  string(APPEND CUDNN_HEADER_CONTENTS "${CUDNN_VERSION_H_CONTENTS}")
+  unset(CUDNN_VERSION_H_CONTENTS)
+elseif(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_version_v8.h")
+  file(READ "${CUDNN_INCLUDE_DIR}/cudnn_version_v8.h" CUDNN_VERSION_H_CONTENTS)
+  string(APPEND CUDNN_HEADER_CONTENTS "${CUDNN_VERSION_H_CONTENTS}")
+  unset(CUDNN_VERSION_H_CONTENTS)
+elseif(EXISTS "${CUDNN_INCLUDE_DIR}/cudnn_version_v7.h")
+  file(READ "${CUDNN_INCLUDE_DIR}/cudnn_version_v7.h" CUDNN_VERSION_H_CONTENTS)
+  string(APPEND CUDNN_HEADER_CONTENTS "${CUDNN_VERSION_H_CONTENTS}")
+  unset(CUDNN_VERSION_H_CONTENTS)
+endif()
+if(CUDNN_HEADER_CONTENTS)
+  string(REGEX MATCH "define CUDNN_MAJOR * +([0-9]+)"
+               _CUDNN_VERSION_MAJOR "${CUDNN_HEADER_CONTENTS}")
+  string(REGEX REPLACE "define CUDNN_MAJOR * +([0-9]+)" "\\1"
+               _CUDNN_VERSION_MAJOR "${_CUDNN_VERSION_MAJOR}")
+  string(REGEX MATCH "define CUDNN_MINOR * +([0-9]+)"
+               _CUDNN_VERSION_MINOR "${CUDNN_HEADER_CONTENTS}")
+  string(REGEX REPLACE "define CUDNN_MINOR * +([0-9]+)" "\\1"
+               _CUDNN_VERSION_MINOR "${_CUDNN_VERSION_MINOR}")
+  string(REGEX MATCH "define CUDNN_PATCHLEVEL * +([0-9]+)"
+               _CUDNN_VERSION_PATCH "${CUDNN_HEADER_CONTENTS}")
+  string(REGEX REPLACE "define CUDNN_PATCHLEVEL * +([0-9]+)" "\\1"
+               _CUDNN_VERSION_PATCH "${_CUDNN_VERSION_PATCH}")
+  if(NOT _CUDNN_VERSION_MAJOR)
+    set(_CUDNN_VERSION "?")
+  else()
+    set(_CUDNN_VERSION "${_CUDNN_VERSION_MAJOR}.${_CUDNN_VERSION_MINOR}.${_CUDNN_VERSION_PATCH}")
+  endif()
+endif()
+
+set(CUDNN_INCLUDE_DIRS ${CUDNN_INCLUDE_DIR})
+set(CUDNN_LIBRARIES ${CUDNN_LIBRARY})
+mark_as_advanced(CUDNN_LIBRARY CUDNN_INCLUDE_DIR)
+
+find_package_handle_standard_args(CUDNN
+      REQUIRED_VARS  CUDNN_INCLUDE_DIR CUDNN_LIBRARY
+      VERSION_VAR    CUDNN_VERSION
+)
+
+set(CUDNN_DLL_DIR ${CUDNN_INCLUDE_DIR})
+list(TRANSFORM CUDNN_DLL_DIR APPEND "/../bin")
+find_file(CUDNN_LIBRARY_DLL NAMES cudnn64_${CUDNN_VERSION_MAJOR}.dll PATHS ${CUDNN_DLL_DIR})
+
+if(CUDNN_FOUND AND NOT TARGET CuDNN::CuDNN AND NOT CMAKE_SCRIPT_MODE_FILE)
+  if(EXISTS "${CUDNN_LIBRARY_DLL}")
+    add_library(CuDNN::CuDNN      SHARED IMPORTED)
+    set_target_properties(CuDNN::CuDNN PROPERTIES
+      IMPORTED_LOCATION                 "${CUDNN_LIBRARY_DLL}"
+      IMPORTED_IMPLIB                   "${CUDNN_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES     "${CUDNN_INCLUDE_DIR}"
+      IMPORTED_LINK_INTERFACE_LANGUAGES "C")
+  else()
+    add_library(CuDNN::CuDNN      UNKNOWN IMPORTED)
+    set_target_properties(CuDNN::CuDNN PROPERTIES
+      IMPORTED_LOCATION                 "${CUDNN_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES     "${CUDNN_INCLUDE_DIR}"
+      IMPORTED_LINK_INTERFACE_LANGUAGES "C")
+  endif()
+endif()
diff --git a/vcpkg/ports/cudnn/portfile.cmake b/vcpkg/ports/cudnn/portfile.cmake
new file mode 100644
index 0000000..80f00f7
--- /dev/null
+++ b/vcpkg/ports/cudnn/portfile.cmake
@@ -0,0 +1,18 @@
+set(MINIMUM_CUDNN_VERSION "7.6.5")
+
+vcpkg_find_cuda(OUT_CUDA_TOOLKIT_ROOT CUDA_TOOLKIT_ROOT OUT_CUDA_VERSION CUDA_VERSION)
+
+include("${CURRENT_PORT_DIR}/FindCUDNN.cmake")
+
+if (CUDNN_INCLUDE_DIR AND CUDNN_LIBRARY AND _CUDNN_VERSION VERSION_GREATER_EQUAL MINIMUM_CUDNN_VERSION)
+  message(STATUS "Found CUDNN ${_CUDNN_VERSION} located on system: (include ${CUDNN_INCLUDE_DIR} lib: ${CUDNN_LIBRARY})")
+  set(VCPKG_POLICY_EMPTY_PACKAGE enabled)
+elseif(VCPKG_TARGET_IS_WINDOWS)
+  message(FATAL_ERROR "Please download CUDNN from official sources (https://developer.nvidia.com/cudnn) and install it")
+else()
+  message(FATAL_ERROR "Please install CUDNN using your system package manager (the same way you installed CUDA). For example: apt install libcudnn8-dev.")
+endif()
+
+file(INSTALL "${CURRENT_PORT_DIR}/FindCUDNN.cmake" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
+file(INSTALL "${CURRENT_PORT_DIR}/usage" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
+file(INSTALL "${CURRENT_PORT_DIR}/vcpkg-cmake-wrapper.cmake" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
diff --git a/vcpkg/ports/cudnn/usage b/vcpkg/ports/cudnn/usage
new file mode 100644
index 0000000..f528e01
--- /dev/null
+++ b/vcpkg/ports/cudnn/usage
@@ -0,0 +1,10 @@
+The package cudnn provides CMake variables:
+
+    find_package(CUDNN REQUIRED)
+    target_link_libraries(main PRIVATE ${CUDNN_LIBRARIES})
+    target_include_directories(main PRIVATE ${CUDNN_INCLUDE_DIRS})
+
+Or the following CMake target:
+
+    find_package(CUDNN REQUIRED)
+    target_link_libraries(main PRIVATE CuDNN::CuDNN)
diff --git a/vcpkg/ports/cudnn/vcpkg-cmake-wrapper.cmake b/vcpkg/ports/cudnn/vcpkg-cmake-wrapper.cmake
new file mode 100644
index 0000000..5a69ede
--- /dev/null
+++ b/vcpkg/ports/cudnn/vcpkg-cmake-wrapper.cmake
@@ -0,0 +1,6 @@
+set(CUDNN_PREV_MODULE_PATH ${CMAKE_MODULE_PATH})
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
+
+_find_package(${ARGS})
+
+set(CMAKE_MODULE_PATH ${CUDNN_PREV_MODULE_PATH})
diff --git a/vcpkg/ports/cudnn/vcpkg.json b/vcpkg/ports/cudnn/vcpkg.json
new file mode 100644
index 0000000..2670c01
--- /dev/null
+++ b/vcpkg/ports/cudnn/vcpkg.json
@@ -0,0 +1,12 @@
+{
+  "name": "cudnn",
+  "version": "7.6.5",
+  "port-version": 16,
+  "description": "NVIDIA's cuDNN deep neural network acceleration library.",
+  "homepage": "https://developer.nvidia.com/cudnn",
+  "license": null,
+  "supports": "(windows & x64 & !uwp) | (linux & x64) | (linux & arm64)",
+  "dependencies": [
+    "cuda"
+  ]
+}