move to own git serverHEADmaster

5 files changed, 377 insertions, 0 deletions

diff --git a/vcpkg/ports/harfbuzz/fix-win32-build.patch b/vcpkg/ports/harfbuzz/fix-win32-build.patch
new file mode 100644
index 0000000..0f15917
--- /dev/null
+++ b/vcpkg/ports/harfbuzz/fix-win32-build.patch
@@ -0,0 +1,16 @@
+diff --git a/src/meson.build b/src/meson.build
+index 87e8962..bdfa797 100644
+--- a/src/meson.build
++++ b/src/meson.build
+@@ -387,6 +387,11 @@ hb_subset_sources = files(
+   'hb-subset.hh',
+ )
+ 
++extra_hb_cpp_args = []
++if cpp.get_argument_syntax() == 'msvc'
++  extra_hb_cpp_args += ['/bigobj']
++endif
++
+ hb_subset_headers = files(
+   'hb-subset.h',
+   'hb-subset-serialize.h'
diff --git a/vcpkg/ports/harfbuzz/harfbuzzConfig.cmake.in b/vcpkg/ports/harfbuzz/harfbuzzConfig.cmake.in
new file mode 100644
index 0000000..88baeef
--- /dev/null
+++ b/vcpkg/ports/harfbuzz/harfbuzzConfig.cmake.in
@@ -0,0 +1,102 @@
+# For old projects where the minimum CMake version is lower than 3.3.
+cmake_policy(SET CMP0012 NEW)
+cmake_policy(SET CMP0054 NEW)
+cmake_policy(SET CMP0057 NEW)
+
+include(CMakeFindDependencyMacro)
+
+# Traditional find module variables (vcpkg polyfill)
+set(HARFBUZZ_INCLUDE_DIR "${VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include/harfbuzz" CACHE INTERNAL "")
+set(HARFBUZZ_INCLUDE_DIRS "${HARFBUZZ_INCLUDE_DIR}")
+set(HARFBUZZ_LIBRARY harfbuzz::harfbuzz CACHE INTERNAL "")
+set(HARFBUZZ_LIBRARIES harfbuzz::harfbuzz)
+
+if(TARGET harfbuzz)
+    set(HARFBUZZ_FOUND TRUE)
+    return()
+endif()
+
+add_library(harfbuzz UNKNOWN IMPORTED)
+add_library(harfbuzz::harfbuzz ALIAS harfbuzz)
+
+find_library(HARFBUZZ_LIBRARY_DEBUG NAMES harfbuzz PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/debug" PATH_SUFFIXES lib NO_DEFAULT_PATH)
+find_library(HARFBUZZ_LIBRARY_RELEASE NAMES harfbuzz PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}" PATH_SUFFIXES lib NO_DEFAULT_PATH)
+if(NOT HARFBUZZ_LIBRARY_DEBUG)
+    set_target_properties(harfbuzz PROPERTIES
+        INTERFACE_INCLUDE_DIRECTORIES "${HARFBUZZ_INCLUDE_DIR}"
+        IMPORTED_CONFIGURATIONS "RELEASE"
+        IMPORTED_LOCATION_RELEASE "${HARFBUZZ_LIBRARY_RELEASE}"
+    )
+else()
+    set_target_properties(harfbuzz PROPERTIES
+        INTERFACE_INCLUDE_DIRECTORIES "${HARFBUZZ_INCLUDE_DIR}"
+        IMPORTED_CONFIGURATIONS "DEBUG;RELEASE"
+        IMPORTED_LOCATION_RELEASE "${HARFBUZZ_LIBRARY_RELEASE}"
+        IMPORTED_LOCATION_DEBUG "${HARFBUZZ_LIBRARY_DEBUG}"
+    )
+endif()
+
+set(HARFBUZZ_FEATURES @FEATURES@)
+
+if(APPLE)
+    find_library(APPLICATIONSERVICES_LIBRARY ApplicationServices)
+    if(APPLICATIONSERVICES_LIBRARY)
+        target_link_libraries(harfbuzz INTERFACE ${APPLICATIONSERVICES_LIBRARY})
+    endif()    
+endif()
+
+find_dependency(freetype CONFIG)
+target_link_libraries(harfbuzz INTERFACE freetype)
+
+if ("graphite2" IN_LIST HARFBUZZ_FEATURES)
+    find_library(GRAPHITE2_LIBRARY_DEBUG NAMES graphite2 PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/debug" PATH_SUFFIXES lib NO_DEFAULT_PATH)
+    find_library(GRAPHITE2_LIBRARY_RELEASE NAMES graphite2 PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}" PATH_SUFFIXES lib NO_DEFAULT_PATH)
+    if(NOT GRAPHITE2_LIBRARY_DEBUG)
+        target_link_libraries(harfbuzz INTERFACE "${GRAPHITE2_LIBRARY_RELEASE}")
+    else()
+        target_link_libraries(harfbuzz INTERFACE "$<$<NOT:$<CONFIG:DEBUG>>:${GRAPHITE2_LIBRARY_RELEASE}>$<$<CONFIG:DEBUG>:${GRAPHITE2_LIBRARY_DEBUG}>")
+    endif()
+endif()
+
+if ("glib" IN_LIST HARFBUZZ_FEATURES)
+    find_library(GLIB_LIBRARY_DEBUG NAMES glib glib-2.0 PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/debug" PATH_SUFFIXES lib NO_DEFAULT_PATH)
+    find_library(GLIB_LIBRARY_RELEASE NAMES glib glib-2.0 PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}" PATH_SUFFIXES lib NO_DEFAULT_PATH)
+    if(NOT GLIB_LIBRARY_DEBUG)
+        target_link_libraries(harfbuzz INTERFACE "${GLIB_LIBRARY_RELEASE}")
+    else()
+        target_link_libraries(harfbuzz INTERFACE "$<$<NOT:$<CONFIG:DEBUG>>:${GLIB_LIBRARY_RELEASE}>$<$<CONFIG:DEBUG>:${GLIB_LIBRARY_DEBUG}>")
+    endif()
+endif()
+
+if ("icu" IN_LIST HARFBUZZ_FEATURES)
+    find_dependency(ICU 61 COMPONENTS uc)
+    target_link_libraries(harfbuzz INTERFACE ICU::uc)
+endif()
+
+add_library(harfbuzz::harfbuzz-subset UNKNOWN IMPORTED)
+
+find_library(HARFBUZZ_SUBSET_LIBRARY_DEBUG 
+    NAMES harfbuzz-subset 
+    PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/debug" 
+    PATH_SUFFIXES lib NO_DEFAULT_PATH)
+find_library(HARFBUZZ_SUBSET_LIBRARY_RELEASE 
+    NAMES harfbuzz-subset 
+    PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}" 
+    PATH_SUFFIXES lib NO_DEFAULT_PATH)
+    
+if(NOT HARFBUZZ_LIBRARY_DEBUG)
+    set_target_properties(harfbuzz::harfbuzz-subset PROPERTIES
+        INTERFACE_INCLUDE_DIRECTORIES "${HARFBUZZ_INCLUDE_DIR}"
+        IMPORTED_CONFIGURATIONS "RELEASE"
+        IMPORTED_LOCATION_RELEASE "${HARFBUZZ_SUBSET_LIBRARY_RELEASE}"
+    )
+else()
+    set_target_properties(harfbuzz::harfbuzz-subset PROPERTIES
+        INTERFACE_INCLUDE_DIRECTORIES "${HARFBUZZ_INCLUDE_DIR}"
+        IMPORTED_CONFIGURATIONS "DEBUG;RELEASE"
+        IMPORTED_LOCATION_RELEASE "${HARFBUZZ_SUBSET_LIBRARY_RELEASE}"
+        IMPORTED_LOCATION_DEBUG "${HARFBUZZ_SUBSET_LIBRARY_DEBUG}"
+    )
+endif()
+
+target_link_libraries(harfbuzz::harfbuzz-subset INTERFACE harfbuzz)
diff --git a/vcpkg/ports/harfbuzz/portfile.cmake b/vcpkg/ports/harfbuzz/portfile.cmake
new file mode 100644
index 0000000..3a33eff
--- /dev/null
+++ b/vcpkg/ports/harfbuzz/portfile.cmake
@@ -0,0 +1,153 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO harfbuzz/harfbuzz
+    REF ${VERSION}
+    SHA512 016cd45720a466740c95bea1bb4eb97d218404536c7498a604d718b9301caf0aa88efef839b2b67823c8b65ae22a335a597580b6ba0dc1602e82287ee3eeb5c1
+    HEAD_REF master
+    PATCHES
+        fix-win32-build.patch
+)
+
+if("icu" IN_LIST FEATURES)
+    list(APPEND FEATURE_OPTIONS -Dicu=enabled) # Enable ICU library unicode functions
+else()
+    list(APPEND FEATURE_OPTIONS -Dicu=disabled)
+endif()
+if("graphite2" IN_LIST FEATURES)
+    list(APPEND FEATURE_OPTIONS -Dgraphite=enabled) #Enable Graphite2 complementary shaper
+else()
+    list(APPEND FEATURE_OPTIONS -Dgraphite=disabled)
+endif()
+if("coretext" IN_LIST FEATURES)
+    list(APPEND FEATURE_OPTIONS -Dcoretext=enabled) # Enable CoreText shaper backend on macOS
+else()
+    list(APPEND FEATURE_OPTIONS -Dcoretext=disabled)
+endif()
+if("directwrite" IN_LIST FEATURES)
+    list(APPEND FEATURE_OPTIONS -Ddirectwrite=enabled) # Enable DirectWrite support on Windows
+else()
+    list(APPEND FEATURE_OPTIONS -Ddirectwrite=disabled)
+endif()
+if("glib" IN_LIST FEATURES)
+    list(APPEND FEATURE_OPTIONS -Dglib=enabled) # Enable GLib unicode functions
+    list(APPEND FEATURE_OPTIONS -Dgobject=enabled) #Enable GObject bindings
+    list(APPEND FEATURE_OPTIONS -Dchafa=disabled)
+else()
+    list(APPEND FEATURE_OPTIONS -Dglib=disabled)
+    list(APPEND FEATURE_OPTIONS -Dgobject=disabled)
+endif()
+if("cairo" IN_LIST FEATURES)
+    list(APPEND FEATURE_OPTIONS -Dcairo=enabled) # Enable Cairo graphics library support
+else()
+    list(APPEND FEATURE_OPTIONS -Dcairo=disabled)
+endif()
+if("freetype" IN_LIST FEATURES)
+    list(APPEND FEATURE_OPTIONS -Dfreetype=enabled) #Enable freetype interop helpers
+else()
+    list(APPEND FEATURE_OPTIONS -Dfreetype=disabled)
+endif()
+if("experimental-api" IN_LIST FEATURES)
+    list(APPEND FEATURE_OPTIONS -Dexperimental_api=true) #Enable experimental api
+else()
+    list(APPEND FEATURE_OPTIONS -Dexperimental_api=false)
+endif()
+if("gdi" IN_LIST FEATURES)
+    list(APPEND FEATURE_OPTIONS -Dgdi=enabled) # enable gdi helpers and uniscribe shaper backend (windows only)
+endif()
+
+if("introspection" IN_LIST FEATURES)
+    list(APPEND OPTIONS_DEBUG -Dgobject=enabled -Dintrospection=disabled)
+    list(APPEND OPTIONS_RELEASE -Dgobject=enabled -Dintrospection=enabled)
+    vcpkg_get_gobject_introspection_programs(PYTHON3 GIR_COMPILER GIR_SCANNER)
+else()
+    list(APPEND OPTIONS -Dintrospection=disabled)
+endif()
+
+set(cxx_link_libraries "")
+if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
+    block(PROPAGATE cxx_link_libraries)
+        vcpkg_list(APPEND VCPKG_CMAKE_CONFIGURE_OPTIONS "-DVCPKG_DEFAULT_VARS_TO_CHECK=CMAKE_C_IMPLICIT_LINK_LIBRARIES;CMAKE_CXX_IMPLICIT_LINK_LIBRARIES")
+        vcpkg_cmake_get_vars(cmake_vars_file)
+        include("${cmake_vars_file}")
+        list(REMOVE_ITEM VCPKG_DETECTED_CMAKE_CXX_IMPLICIT_LINK_LIBRARIES ${VCPKG_DETECTED_CMAKE_C_IMPLICIT_LINK_LIBRARIES})
+        list(TRANSFORM VCPKG_DETECTED_CMAKE_CXX_IMPLICIT_LINK_LIBRARIES PREPEND "-l")
+        string(JOIN " " cxx_link_libraries ${VCPKG_DETECTED_CMAKE_CXX_IMPLICIT_LINK_LIBRARIES})
+    endblock()
+endif()
+
+vcpkg_configure_meson(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        ${FEATURE_OPTIONS}
+        -Ddocs=disabled          # Generate documentation with gtk-doc
+        -Dtests=disabled
+        -Dbenchmark=disabled
+        ${OPTIONS}
+    OPTIONS_DEBUG
+        ${OPTIONS_DEBUG}
+    OPTIONS_RELEASE
+        ${OPTIONS_RELEASE}
+    ADDITIONAL_BINARIES
+        glib-genmarshal='${CURRENT_HOST_INSTALLED_DIR}/tools/glib/glib-genmarshal'
+        glib-mkenums='${CURRENT_HOST_INSTALLED_DIR}/tools/glib/glib-mkenums'
+        g-ir-compiler='${GIR_COMPILER}'
+        g-ir-scanner='${GIR_SCANNER}'
+)
+
+vcpkg_install_meson(ADD_BIN_TO_PATH)
+vcpkg_copy_pdbs()
+vcpkg_fixup_pkgconfig()
+
+if(cxx_link_libraries)
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/lib/pkgconfig/harfbuzz.pc"
+        "(Libs:[^\r\n]*)"
+        "\\1 ${cxx_link_libraries}"
+        REGEX
+    )
+    if(NOT VCPKG_BUILD_TYPE)
+        vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig/harfbuzz.pc"
+            "(Libs:[^\r\n]*)"
+            "\\1 ${cxx_link_libraries}"
+            REGEX
+        )
+    endif()
+endif()
+
+if(VCPKG_TARGET_IS_WINDOWS)
+    file(GLOB pc_files 
+        "${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig/*.pc" 
+        "${CURRENT_PACKAGES_DIR}/lib/pkgconfig/*.pc"
+    )
+    foreach(pc_file IN LISTS pc_files)
+        vcpkg_replace_string("${pc_file}"
+            "\\$\\{prefix\}\\/lib\\/([a-zA-Z0-9\-]*)\\.lib" 
+            "-l\\1"
+            REGEX
+            IGNORE_UNCHANGED
+        )
+    endforeach()
+endif()
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/lib/cmake")
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/lib/cmake")
+configure_file("${CMAKE_CURRENT_LIST_DIR}/harfbuzzConfig.cmake.in"
+        "${CURRENT_PACKAGES_DIR}/share/${PORT}/harfbuzzConfig.cmake" @ONLY)
+
+vcpkg_list(SET TOOL_NAMES)
+if("glib" IN_LIST FEATURES)
+    vcpkg_list(APPEND TOOL_NAMES hb-subset hb-shape hb-info)
+    if("cairo" IN_LIST FEATURES)
+        vcpkg_list(APPEND TOOL_NAMES hb-view)
+    endif()
+endif()
+if(TOOL_NAMES)
+    vcpkg_copy_tools(TOOL_NAMES ${TOOL_NAMES} AUTO_CLEAN)
+endif()
+
+if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
+    file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/bin" "${CURRENT_PACKAGES_DIR}/debug/bin")
+endif()
+
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/COPYING")
+
+file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/usage" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
diff --git a/vcpkg/ports/harfbuzz/usage b/vcpkg/ports/harfbuzz/usage
new file mode 100644
index 0000000..b98565b
--- /dev/null
+++ b/vcpkg/ports/harfbuzz/usage
@@ -0,0 +1,15 @@
+harfbuzz provides CMake targets:

+

+  find_package(harfbuzz CONFIG REQUIRED)

+  # HarfBuzz font subsetter

+  target_link_libraries(main PRIVATE harfbuzz::harfbuzz-subset)

+  # HarfBuzz text shaping library

+  target_link_libraries(main PRIVATE harfbuzz::harfbuzz)

+

+harfbuzz provides pkg-config modules:

+

+  # HarfBuzz font subsetter

+  harfbuzz-subset

+

+  # HarfBuzz text shaping library

+  harfbuzz

diff --git a/vcpkg/ports/harfbuzz/vcpkg.json b/vcpkg/ports/harfbuzz/vcpkg.json
new file mode 100644
index 0000000..86ec5ec
--- /dev/null
+++ b/vcpkg/ports/harfbuzz/vcpkg.json
@@ -0,0 +1,91 @@
+{
+  "name": "harfbuzz",
+  "version": "12.2.0",
+  "description": "HarfBuzz OpenType text shaping engine",
+  "homepage": "https://github.com/harfbuzz/harfbuzz",
+  "license": "MIT-Modern-Variant",
+  "supports": "!uwp",
+  "dependencies": [
+    {
+      "name": "vcpkg-tool-meson",
+      "host": true
+    }
+  ],
+  "default-features": [
+    "freetype"
+  ],
+  "features": {
+    "cairo": {
+      "description": "Enable Cairo graphics library support",
+      "dependencies": [
+        {
+          "name": "cairo",
+          "default-features": false,
+          "features": [
+            "freetype"
+          ]
+        }
+      ]
+    },
+    "coretext": {
+      "description": "Enable CoreText shaper backend on macOS",
+      "supports": "osx"
+    },
+    "directwrite": {
+      "description": "Enable DirectWrite support on Windows",
+      "supports": "windows"
+    },
+    "experimental-api": {
+      "description": "Enable experimental api"
+    },
+    "freetype": {
+      "description": "Enable FreeType support",
+      "dependencies": [
+        {
+          "name": "freetype",
+          "default-features": false
+        }
+      ]
+    },
+    "gdi": {
+      "description": "Enable GDI/Uniscribe support on Windows",
+      "supports": "windows"
+    },
+    "glib": {
+      "description": "Glib Unicode callbacks support",
+      "dependencies": [
+        "glib",
+        {
+          "name": "glib",
+          "host": true
+        }
+      ]
+    },
+    "graphite2": {
+      "description": "Graphite2 shaper support",
+      "dependencies": [
+        "graphite2"
+      ]
+    },
+    "icu": {
+      "description": "icu support for harfbuzz",
+      "dependencies": [
+        "icu"
+      ]
+    },
+    "introspection": {
+      "description": "build with introspection",
+      "supports": "!static",
+      "dependencies": [
+        "gobject-introspection",
+        {
+          "name": "harfbuzz",
+          "default-features": false,
+          "features": [
+            "glib"
+          ]
+        }
+      ]
+    }
+  }
+}