aboutsummaryrefslogtreecommitdiff
path: root/vcpkg/ports/breakpad
diff options
context:
space:
mode:
Diffstat (limited to 'vcpkg/ports/breakpad')
-rw-r--r--vcpkg/ports/breakpad/CMakeLists.txt221
-rw-r--r--vcpkg/ports/breakpad/add-algorithm-1.patch12
-rw-r--r--vcpkg/ports/breakpad/check_getcontext.cc9
-rw-r--r--vcpkg/ports/breakpad/portfile.cmake69
-rw-r--r--vcpkg/ports/breakpad/unofficial-breakpadConfig.cmake6
-rw-r--r--vcpkg/ports/breakpad/vcpkg.json33
6 files changed, 350 insertions, 0 deletions
diff --git a/vcpkg/ports/breakpad/CMakeLists.txt b/vcpkg/ports/breakpad/CMakeLists.txt
new file mode 100644
index 0000000..53d24c7
--- /dev/null
+++ b/vcpkg/ports/breakpad/CMakeLists.txt
@@ -0,0 +1,221 @@
+cmake_minimum_required(VERSION 3.8)
+project(breakpad CXX)
+
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+
+add_definitions(
+ -DNOMINMAX
+ -DUNICODE
+ -DWIN32_LEAN_AND_MEAN
+ -D_CRT_SECURE_NO_WARNINGS
+ -D_CRT_SECURE_NO_DEPRECATE
+ -D_CRT_NONSTDC_NO_DEPRECATE
+)
+
+set(CMAKE_DEBUG_POSTFIX d)
+
+string(COMPARE EQUAL "${CMAKE_BUILD_TYPE}" "Release" DEFAULT_INSTALL_HEADERS)
+option(INSTALL_HEADERS "Install header files" ${DEFAULT_INSTALL_HEADERS})
+option(INSTALL_TOOLS "Install tools" OFF)
+
+# libbreakpad target
+if(NOT CMAKE_SYSTEM_NAME STREQUAL Android)
+ file(GLOB_RECURSE LIBBREAKPAD_SOURCES src/processor/*.cc)
+ if(WIN32)
+ list(FILTER LIBBREAKPAD_SOURCES EXCLUDE REGEX
+ "_unittest|_selftest|synth_minidump|/tests|/testdata|/linux|/mac|/android|/solaris|microdump_stackwalk|minidump_dump|minidump_stackwalk|disassembler_objdump.cc")
+ elseif(APPLE)
+ list(FILTER LIBBREAKPAD_SOURCES EXCLUDE REGEX
+ "_unittest|_selftest|synth_minidump|/tests|/testdata|/linux|/windows|/android|/solaris|microdump_stackwalk|minidump_dump|minidump_stackwalk|disassembler_objdump.cc")
+ else()
+ list(FILTER LIBBREAKPAD_SOURCES EXCLUDE REGEX
+ "_unittest|_selftest|synth_minidump|/tests|/testdata|/mac|/windows|/android|/solaris|microdump_stackwalk|minidump_dump|minidump_stackwalk")
+ endif()
+
+ find_library(LIBDISASM_LIB NAMES libdisasmd libdisasm)
+
+ add_library(libbreakpad ${LIBBREAKPAD_SOURCES})
+ target_link_libraries(libbreakpad PRIVATE ${LIBDISASM_LIB})
+
+ target_include_directories(libbreakpad
+ PUBLIC
+ $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>
+ $<INSTALL_INTERFACE:include>
+ )
+
+ set(TARGETS libbreakpad)
+endif()
+
+# libbreakpad_client target
+if(CMAKE_SYSTEM_NAME STREQUAL Android)
+ file(READ "android/google_breakpad/Android.mk" android_mk)
+ string(REGEX MATCHALL "src/[^\n]*\\.cc" LIBBREAKPAD_CLIENT_SOURCES "${android_mk}")
+else()
+ if(WIN32)
+ file(GLOB_RECURSE LIBBREAKPAD_CLIENT_SOURCES src/client/windows/*.cc src/common/windows/*.cc)
+ include_directories("$ENV{VSINSTALLDIR}/DIA SDK/include")
+ elseif(APPLE)
+ add_definitions(-DHAVE_MACH_O_NLIST_H)
+ file(GLOB_RECURSE LIBBREAKPAD_CLIENT_SOURCES src/client/mac/*.cc src/common/mac/*.cc)
+ list(APPEND LIBBREAKPAD_CLIENT_SOURCES src/common/mac/MachIPC.mm)
+ else()
+ add_definitions(-DHAVE_A_OUT_H)
+ file(GLOB_RECURSE LIBBREAKPAD_CLIENT_SOURCES src/client/linux/*.cc src/common/linux/*.cc)
+ endif()
+ file(GLOB LIBBREAKPAD_COMMON_SOURCES src/common/*.cc src/common/*.c src/client/*.cc)
+ list(APPEND LIBBREAKPAD_CLIENT_SOURCES ${LIBBREAKPAD_COMMON_SOURCES})
+endif()
+list(FILTER LIBBREAKPAD_CLIENT_SOURCES EXCLUDE REGEX "/sender|/tests|/unittests|/testcases|_unittest|_test")
+if(WIN32)
+ list(FILTER LIBBREAKPAD_CLIENT_SOURCES EXCLUDE REGEX "language.cc|path_helper.cc|stabs_to_module.cc|stabs_reader.cc|minidump_file_writer.cc")
+elseif(NOT APPLE)
+ try_compile(HAVE_GETCONTEXT ${CMAKE_BINARY_DIR}/check_getcontext ${CMAKE_CURRENT_LIST_DIR}/check_getcontext.cc OUTPUT_VARIABLE BUILD_OUT)
+ if (NOT HAVE_GETCONTEXT)
+ enable_language(ASM)
+ list(APPEND LIBBREAKPAD_CLIENT_SOURCES src/common/linux/breakpad_getcontext.S)
+ endif()
+endif()
+
+add_library(libbreakpad_client ${LIBBREAKPAD_CLIENT_SOURCES})
+if(WIN32)
+ target_link_libraries(libbreakpad_client PRIVATE wininet.lib)
+elseif(APPLE)
+ find_library(CoreFoundation_FRAMEWORK CoreFoundation)
+ target_link_libraries(libbreakpad_client PRIVATE ${CoreFoundation_FRAMEWORK})
+else()
+ find_library(PTHREAD_LIBRARIES pthread)
+ if(PTHREAD_LIBRARIES)
+ target_link_libraries(libbreakpad_client PRIVATE ${PTHREAD_LIBRARIES})
+ endif()
+ if (HAVE_GETCONTEXT)
+ target_compile_definitions(libbreakpad_client PRIVATE HAVE_GETCONTEXT=1)
+ endif()
+endif()
+
+set(USED_ZLIB OFF)
+if(LINUX AND NOT CMAKE_SYSTEM_NAME STREQUAL Android)
+ # src/common/linux/dump_symbols.cc wants zlib.h
+ find_package(ZLIB REQUIRED)
+ target_link_libraries(libbreakpad_client PRIVATE ZLIB::ZLIB)
+ set(USED_ZLIB ON)
+endif()
+
+target_include_directories(libbreakpad_client
+ PUBLIC
+ $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>
+ $<INSTALL_INTERFACE:include>
+)
+list(APPEND TARGETS libbreakpad_client)
+
+if(INSTALL_TOOLS)
+ if(LINUX)
+ add_executable(microdump_stackwalk
+ src/processor/microdump_stackwalk.cc)
+ target_link_libraries(microdump_stackwalk PRIVATE libbreakpad libbreakpad_client)
+ install(TARGETS microdump_stackwalk DESTINATION bin)
+
+ add_executable(minidump_dump
+ src/processor/minidump_dump.cc)
+ target_link_libraries(minidump_dump PRIVATE libbreakpad libbreakpad_client)
+ install(TARGETS minidump_dump DESTINATION bin)
+
+ add_executable(minidump_stackwalk
+ src/processor/minidump_stackwalk.cc)
+ target_link_libraries(minidump_stackwalk PRIVATE libbreakpad libbreakpad_client)
+ install(TARGETS minidump_stackwalk DESTINATION bin)
+
+ add_executable(core2md
+ src/tools/linux/core2md/core2md.cc)
+ target_link_libraries(core2md PRIVATE libbreakpad_client)
+ install(TARGETS core2md DESTINATION bin)
+
+ add_executable(pid2md
+ src/tools/linux/pid2md/pid2md.cc)
+ target_link_libraries(pid2md PRIVATE libbreakpad_client)
+ install(TARGETS pid2md DESTINATION bin)
+
+ add_executable(dump_syms
+ src/common/dwarf_cfi_to_module.cc
+ src/common/dwarf_cu_to_module.cc
+ src/common/dwarf_line_to_module.cc
+ src/common/dwarf_range_list_handler.cc
+ src/common/language.cc
+ src/common/module.cc
+ src/common/path_helper.cc
+ src/common/stabs_reader.cc
+ src/common/stabs_to_module.cc
+ src/common/dwarf/bytereader.cc
+ src/common/dwarf/dwarf2diehandler.cc
+ src/common/dwarf/dwarf2reader.cc
+ src/common/dwarf/elf_reader.cc
+ src/tools/linux/dump_syms/dump_syms.cc)
+ target_link_libraries(dump_syms PRIVATE libbreakpad_client)
+ install(TARGETS dump_syms DESTINATION bin)
+
+ add_executable(minidump-2-core
+ src/common/linux/memory_mapped_file.cc
+ src/tools/linux/md2core/minidump-2-core.cc)
+ target_link_libraries(minidump-2-core PRIVATE libbreakpad_client)
+ install(TARGETS minidump-2-core DESTINATION bin)
+
+ add_executable(minidump_upload
+ src/common/linux/http_upload.cc
+ src/tools/linux/symupload/minidump_upload.cc)
+ target_link_libraries(minidump_upload PRIVATE libbreakpad_client ${CMAKE_DL_LIBS})
+ install(TARGETS minidump_upload DESTINATION bin)
+
+ add_executable(sym_upload
+ src/common/linux/http_upload.cc
+ src/common/linux/libcurl_wrapper.cc
+ src/common/linux/symbol_collector_client.cc
+ src/common/linux/symbol_upload.cc
+ src/tools/linux/symupload/sym_upload.cc)
+ target_link_libraries(sym_upload PRIVATE libbreakpad_client ${CMAKE_DL_LIBS})
+ install(TARGETS sym_upload DESTINATION bin)
+
+ add_executable(core_handler
+ src/tools/linux/core_handler/core_handler.cc)
+ target_link_libraries(core_handler PRIVATE libbreakpad_client)
+ install(TARGETS core_handler DESTINATION bin)
+ endif()
+endif()
+
+# installation
+install(TARGETS ${TARGETS} EXPORT unofficial-breakpad-targets
+ RUNTIME DESTINATION bin
+ LIBRARY DESTINATION lib
+ ARCHIVE DESTINATION lib
+)
+
+if(INSTALL_HEADERS)
+ if(WIN32)
+ set(HEADER_EXCLUDE_REGEX "/apple|/ios|/linux|/mac|/solaris|/android|/dwarf|/tests|/testdata|/unittests")
+ elseif(APPLE)
+ set(HEADER_EXCLUDE_REGEX "/apple|/ios|/linux|/windows|/solaris|/android|/dwarf|/tests|/testdata|/unittests|/sender|/testapp|\.xcodeproj|/gcov")
+ else()
+ set(HEADER_EXCLUDE_REGEX "/apple|/ios|/windows|/mac|/solaris|/android|/dwarf|/tests|/testdata|/unittests")
+ install(
+ DIRECTORY src/third_party/lss
+ DESTINATION include/third_party
+ FILES_MATCHING PATTERN "*.h"
+ REGEX "${HEADER_EXCLUDE_REGEX}" EXCLUDE
+ )
+ endif()
+ install(
+ DIRECTORY src/client src/common src/google_breakpad
+ DESTINATION include/
+ FILES_MATCHING
+ PATTERN "*.h"
+ REGEX ${HEADER_EXCLUDE_REGEX} EXCLUDE
+ )
+endif()
+
+install(
+ EXPORT unofficial-breakpad-targets
+ FILE unofficial-breakpadTargets.cmake
+ NAMESPACE unofficial::breakpad::
+ DESTINATION share/unofficial-breakpad
+)
+
+configure_file("${CMAKE_CURRENT_LIST_DIR}/unofficial-breakpadConfig.cmake" "${CMAKE_INSTALL_PREFIX}/share/unofficial-breakpad/unofficial-breakpadConfig.cmake" @ONLY)
diff --git a/vcpkg/ports/breakpad/add-algorithm-1.patch b/vcpkg/ports/breakpad/add-algorithm-1.patch
new file mode 100644
index 0000000..20b13ed
--- /dev/null
+++ b/vcpkg/ports/breakpad/add-algorithm-1.patch
@@ -0,0 +1,12 @@
+diff --git a/src/common/string_view.h b/src/common/string_view.h
+index a8e15922..bcaa7b96 100644
+--- a/src/common/string_view.h
++++ b/src/common/string_view.h
+@@ -29,6 +29,7 @@
+ #ifndef COMMON_STRING_VIEW_H__
+ #define COMMON_STRING_VIEW_H__
+
++#include <algorithm>
+ #include <cassert>
+ #include <cstring>
+ #include <ostream>
diff --git a/vcpkg/ports/breakpad/check_getcontext.cc b/vcpkg/ports/breakpad/check_getcontext.cc
new file mode 100644
index 0000000..7621474
--- /dev/null
+++ b/vcpkg/ports/breakpad/check_getcontext.cc
@@ -0,0 +1,9 @@
+#include <ucontext.h>
+#include <cstddef>
+
+int main() {
+ ucontext_t context;
+ getcontext(&context);
+
+ return 0;
+}
diff --git a/vcpkg/ports/breakpad/portfile.cmake b/vcpkg/ports/breakpad/portfile.cmake
new file mode 100644
index 0000000..112a9ee
--- /dev/null
+++ b/vcpkg/ports/breakpad/portfile.cmake
@@ -0,0 +1,69 @@
+vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
+
+string(REPLACE "-" "." BREAKPAD-VERSION "${VERSION}")
+vcpkg_from_github(
+ OUT_SOURCE_PATH SOURCE_PATH
+ REPO google/breakpad
+ REF "v${BREAKPAD-VERSION}"
+ SHA512 88c691983c6c92fd5321d729c8eec059914293de0e91fe1d429a6247f3b7299f32ec4938eccbbe2c95a9ca507db14d73a1c9798d5fce79a8b474c3c216f0951a
+ HEAD_REF master
+ PATCHES
+ add-algorithm-1.patch
+)
+
+if(VCPKG_HOST_IS_LINUX OR VCPKG_TARGET_IS_LINUX OR VCPKG_TARGET_IS_ANDROID)
+ vcpkg_from_git(
+ OUT_SOURCE_PATH LSS_SOURCE_PATH
+ URL https://chromium.googlesource.com/linux-syscall-support
+ REF 9719c1e1e676814c456b55f5f070eabad6709d31
+ )
+
+ file(RENAME "${LSS_SOURCE_PATH}" "${SOURCE_PATH}/src/third_party/lss")
+endif()
+
+file(COPY
+ "${CMAKE_CURRENT_LIST_DIR}/check_getcontext.cc"
+ "${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt"
+ "${CMAKE_CURRENT_LIST_DIR}/unofficial-breakpadConfig.cmake"
+ DESTINATION
+ "${SOURCE_PATH}")
+
+vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
+ FEATURES
+ "tools" INSTALL_TOOLS
+)
+
+vcpkg_cmake_configure(
+ SOURCE_PATH "${SOURCE_PATH}"
+ OPTIONS
+ ${FEATURE_OPTIONS}
+ OPTIONS_RELEASE
+ -DINSTALL_HEADERS=ON
+)
+
+vcpkg_cmake_install()
+file(REMOVE_RECURSE
+ "${CURRENT_PACKAGES_DIR}/include/client/linux/data"
+ "${CURRENT_PACKAGES_DIR}/include/client/linux/sender")
+
+if("tools" IN_LIST FEATURES)
+ vcpkg_copy_tools(
+ TOOL_NAMES
+ microdump_stackwalk
+ minidump_dump
+ minidump_stackwalk
+ core2md
+ pid2md
+ dump_syms
+ minidump-2-core
+ minidump_upload
+ sym_upload
+ core_handler
+ AUTO_CLEAN)
+endif()
+
+vcpkg_cmake_config_fixup(PACKAGE_NAME unofficial-breakpad)
+
+vcpkg_copy_pdbs()
+
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/LICENSE")
diff --git a/vcpkg/ports/breakpad/unofficial-breakpadConfig.cmake b/vcpkg/ports/breakpad/unofficial-breakpadConfig.cmake
new file mode 100644
index 0000000..67d5598
--- /dev/null
+++ b/vcpkg/ports/breakpad/unofficial-breakpadConfig.cmake
@@ -0,0 +1,6 @@
+if(@USED_ZLIB@)
+ include(CMakeFindDependencyMacro)
+ find_dependency(ZLIB)
+endif()
+
+include("${CMAKE_CURRENT_LIST_DIR}/unofficial-breakpadTargets.cmake")
diff --git a/vcpkg/ports/breakpad/vcpkg.json b/vcpkg/ports/breakpad/vcpkg.json
new file mode 100644
index 0000000..1010509
--- /dev/null
+++ b/vcpkg/ports/breakpad/vcpkg.json
@@ -0,0 +1,33 @@
+{
+ "name": "breakpad",
+ "version-date": "2024-02-16",
+ "description": "a set of client and server components which implement a crash-reporting system.",
+ "homepage": "https://github.com/google/breakpad",
+ "license": "BSD-3-Clause",
+ "supports": "!uwp & (!windows | !arm) & (!windows | !arm64)",
+ "dependencies": [
+ {
+ "name": "atl",
+ "platform": "windows"
+ },
+ "libdisasm",
+ {
+ "name": "vcpkg-cmake",
+ "host": true
+ },
+ {
+ "name": "vcpkg-cmake-config",
+ "host": true
+ },
+ {
+ "name": "zlib",
+ "platform": "linux"
+ }
+ ],
+ "features": {
+ "tools": {
+ "description": "Build breakpad tools",
+ "supports": "linux"
+ }
+ }
+}
generated by cgit v1.2.3 (git 2.39.1) at 2026-02-15 02:40:02 +0000