1 files changed, 59 insertions, 0 deletions
diff --git a/vcpkg/ports/glbinding/portfile.cmake b/vcpkg/ports/glbinding/portfile.cmake
new file mode 100644
index 0000000..bc6d11c
--- /dev/null
+++ b/vcpkg/ports/glbinding/portfile.cmake
@@ -0,0 +1,59 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO cginternals/glbinding
+    REF v3.1.0
+    SHA512 d7294c9a0dc47a7c107b134e5dfa78c5812fc6bf739b9fd778fa7ce946d5ea971839a65c3985e0915fd75311e4a85fb221d33a71856c460199eab0e7622f7151
+    HEAD_REF master
+    PATCHES
+        0001_force-system-install.patch
+        0002_fix-uwpmacro.patch
+        0003_fix-cmake-configs-paths.patch
+        0004_fix-config-expected-paths.patch
+)
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        -DOPTION_BUILD_TESTS=OFF
+        -DOPTION_BUILD_TOOLS=OFF
+        -DOPTION_BUILD_EXAMPLES=OFF
+        -DGIT_REV=0
+        -DCMAKE_DISABLE_FIND_PACKAGE_cpplocate=ON
+        -DOPTION_BUILD_EXAMPLES=OFF
+    MAYBE_UNUSED_VARIABLES
+        CMAKE_DISABLE_FIND_PACKAGE_cpplocate
+)
+
+vcpkg_cmake_install()
+vcpkg_cmake_config_fixup()
+vcpkg_copy_pdbs()
+
+## _IMPORT_PREFIX needs to go up one extra level in the directory tree.
+file(GLOB_RECURSE TARGET_CMAKES "${CURRENT_PACKAGES_DIR}/*-export.cmake")
+foreach(TARGET_CMAKE IN LISTS TARGET_CMAKES)
+    file(READ ${TARGET_CMAKE} _contents)
+    string(REPLACE
+[[
+get_filename_component(_IMPORT_PREFIX "${CMAKE_CURRENT_LIST_FILE}" PATH)
+get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
+get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
+]]
+[[
+get_filename_component(_IMPORT_PREFIX "${CMAKE_CURRENT_LIST_FILE}" PATH)
+get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
+get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
+get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
+]]
+        _contents "${_contents}")
+    file(WRITE ${TARGET_CMAKE} "${_contents}")
+endforeach()
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
+
+# Remove files already published by egl-registry
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/include/KHR")
+
+# Handle copyright
+file(RENAME "${CURRENT_PACKAGES_DIR}/share/${PORT}/LICENSE" "${CURRENT_PACKAGES_DIR}/share/${PORT}/copyright")
+configure_file("${CMAKE_CURRENT_LIST_DIR}/usage" "${CURRENT_PACKAGES_DIR}/share/${PORT}/usage" @ONLY)