4 files changed, 74 insertions, 0 deletions
diff --git a/vcpkg/ports/h5py-lzf/CMakeLists.txt b/vcpkg/ports/h5py-lzf/CMakeLists.txt
new file mode 100644
index 0000000..a90a1f7
--- /dev/null
+++ b/vcpkg/ports/h5py-lzf/CMakeLists.txt
@@ -0,0 +1,23 @@
+cmake_minimum_required(VERSION 3.13)
+project(h5py-lzf LANGUAGES C)
+
+find_package(hdf5 CONFIG REQUIRED)
+find_package(unofficial-liblzf CONFIG REQUIRED)
+
+add_library(h5py-lzf STATIC lzf_filter.c)
+target_include_directories(h5py-lzf PUBLIC $<INSTALL_INTERFACE:include>)
+target_link_libraries(h5py-lzf PRIVATE
+    unofficial::liblzf::liblzf
+    $<IF:$<TARGET_EXISTS:hdf5::hdf5-shared>,hdf5::hdf5-shared,hdf5::hdf5-static>
+)
+
+install(FILES lzf_filter.h DESTINATION include)
+install(TARGETS h5py-lzf
+    EXPORT unofficial-h5py-lzf-targets
+    ARCHIVE DESTINATION lib
+    LIBRARY DESTINATION lib
+)
+install(EXPORT unofficial-h5py-lzf-targets
+    NAMESPACE unofficial::h5py-lzf::
+    DESTINATION share/unofficial-h5py-lzf
+)
diff --git a/vcpkg/ports/h5py-lzf/portfile.cmake b/vcpkg/ports/h5py-lzf/portfile.cmake
new file mode 100644
index 0000000..91ff22e
--- /dev/null
+++ b/vcpkg/ports/h5py-lzf/portfile.cmake
@@ -0,0 +1,25 @@
+vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO h5py/h5py
+    REF ${VERSION}
+    SHA512 d741b377605b2aef2847731ddb8bc9fc06eece0882ccc32b0f74e52a50ca217a9813298df77c6ae4a9eca3ed1148f58314746308d341fb58200a25dab3cbd5e2
+    HEAD_REF master
+)
+file(REMOVE_RECURSE "${SOURCE_PATH}/lzf/lzf")
+
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt" DESTINATION "${SOURCE_PATH}/lzf")
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}/lzf"
+)
+
+vcpkg_cmake_install()
+vcpkg_copy_pdbs()
+vcpkg_cmake_config_fixup(PACKAGE_NAME unofficial-h5py-lzf)
+file(COPY "${CURRENT_PORT_DIR}/unofficial-h5py-lzf-config.cmake" DESTINATION "${CURRENT_PACKAGES_DIR}/share/unofficial-h5py-lzf")
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include" "${CURRENT_PACKAGES_DIR}/debug/share")
+
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/lzf/LICENSE.txt")
diff --git a/vcpkg/ports/h5py-lzf/unofficial-h5py-lzf-config.cmake b/vcpkg/ports/h5py-lzf/unofficial-h5py-lzf-config.cmake
new file mode 100644
index 0000000..488dee3
--- /dev/null
+++ b/vcpkg/ports/h5py-lzf/unofficial-h5py-lzf-config.cmake
@@ -0,0 +1,4 @@
+include(CMakeFindDependencyMacro)
+find_dependency(hdf5 CONFIG)
+find_dependency(unofficial-liblzf CONFIG)
+include("${CMAKE_CURRENT_LIST_DIR}/unofficial-h5py-lzf-targets.cmake")
diff --git a/vcpkg/ports/h5py-lzf/vcpkg.json b/vcpkg/ports/h5py-lzf/vcpkg.json
new file mode 100644
index 0000000..1b55f9f
--- /dev/null
+++ b/vcpkg/ports/h5py-lzf/vcpkg.json
@@ -0,0 +1,22 @@
+{
+  "name": "h5py-lzf",
+  "version": "3.12.1",
+  "description": "The LZF filter is an alternative DEFLATE-style compressor for HDF5 datasets.",
+  "homepage": "https://github.com/h5py/h5py/tree/master/lzf",
+  "license": "BSD-3-Clause",
+  "dependencies": [
+    {
+      "name": "hdf5",
+      "default-features": false
+    },
+    "liblzf",
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ]
+}