3 files changed, 94 insertions, 0 deletions
diff --git a/vcpkg/ports/implot/CMakeLists.txt b/vcpkg/ports/implot/CMakeLists.txt
new file mode 100644
index 0000000..6807c55
--- /dev/null
+++ b/vcpkg/ports/implot/CMakeLists.txt
@@ -0,0 +1,52 @@
+cmake_minimum_required(VERSION 3.8)
+project(implot CXX)
+
+find_package(imgui CONFIG REQUIRED)
+get_target_property(IMGUI_INCLUDE_DIRS imgui::imgui
+    INTERFACE_INCLUDE_DIRECTORIES
+)
+
+set(CMAKE_DEBUG_POSTFIX d)
+
+add_library(${PROJECT_NAME} "")
+add_library(${PROJECT_NAME}::${PROJECT_NAME} ALIAS ${PROJECT_NAME})
+target_compile_features(${PROJECT_NAME} PUBLIC cxx_std_11)
+target_include_directories(
+	${PROJECT_NAME}
+	PUBLIC
+	   	$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+		$<INSTALL_INTERFACE:include>
+	PRIVATE
+		${IMGUI_INCLUDE_DIRS}
+)
+
+target_sources(
+	${PROJECT_NAME}
+	PRIVATE
+		${CMAKE_CURRENT_SOURCE_DIR}/implot.cpp
+		${CMAKE_CURRENT_SOURCE_DIR}/implot_items.cpp
+		${CMAKE_CURRENT_SOURCE_DIR}/implot_demo.cpp
+)
+
+install(
+	TARGETS ${PROJECT_NAME}
+	EXPORT ${PROJECT_NAME}_target
+	ARCHIVE DESTINATION lib
+	LIBRARY DESTINATION lib
+	RUNTIME DESTINATION bin
+)
+
+if(NOT IMPLOT_SKIP_HEADERS)
+    install(FILES
+        ${CMAKE_CURRENT_SOURCE_DIR}/implot.h
+		${CMAKE_CURRENT_SOURCE_DIR}/implot_internal.h
+        DESTINATION include
+    )
+endif()
+
+install(
+	EXPORT ${PROJECT_NAME}_target
+	NAMESPACE ${PROJECT_NAME}::
+	FILE ${PROJECT_NAME}-config.cmake
+	DESTINATION share/${PROJECT_NAME}
+)
diff --git a/vcpkg/ports/implot/portfile.cmake b/vcpkg/ports/implot/portfile.cmake
new file mode 100644
index 0000000..7bda017
--- /dev/null
+++ b/vcpkg/ports/implot/portfile.cmake
@@ -0,0 +1,24 @@
+vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO epezent/implot
+    REF v${VERSION}
+    SHA512 117cb08122d900e7db857897bfec4c9ac3300a1d429c8f0303415bc693840baa9bbbb91ca3f13853d8efd3a6ebf538b7114401d4fbfe0d067256e58cbdbd4919
+    HEAD_REF master
+)
+
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt" DESTINATION "${SOURCE_PATH}")
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS_DEBUG
+        -DIMPLOT_SKIP_HEADERS=ON
+)
+
+vcpkg_cmake_install()
+
+vcpkg_copy_pdbs()
+vcpkg_cmake_config_fixup()
+
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/LICENSE")
diff --git a/vcpkg/ports/implot/vcpkg.json b/vcpkg/ports/implot/vcpkg.json
new file mode 100644
index 0000000..70c71fb
--- /dev/null
+++ b/vcpkg/ports/implot/vcpkg.json
@@ -0,0 +1,18 @@
+{
+  "name": "implot",
+  "version": "0.16",
+  "description": "Advanced 2D Plotting for Dear ImGui",
+  "homepage": "https://github.com/epezent/implot",
+  "license": "MIT",
+  "dependencies": [
+    "imgui",
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ]
+}