1 files changed, 72 insertions, 0 deletions
diff --git a/vcpkg/ports/kf5service/portfile.cmake b/vcpkg/ports/kf5service/portfile.cmake
new file mode 100644
index 0000000..14e576d
--- /dev/null
+++ b/vcpkg/ports/kf5service/portfile.cmake
@@ -0,0 +1,72 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO KDE/kservice
+    REF v5.98.0
+    SHA512 c2cfe77418099883838deb3b4143a48e31845f8ea81b335fe86214d23c3df3233be96037e104593dd852b10363a0f2dd28d7cfa04ced608881c77f8a6524f83f
+    HEAD_REF master
+)
+
+if(VCPKG_TARGET_IS_OSX)
+    # On Darwin platform, the bundled version of 'bison' may be too old (< 3.0).
+    vcpkg_find_acquire_program(BISON)
+    execute_process(
+        COMMAND ${BISON} --version
+        OUTPUT_VARIABLE BISON_OUTPUT
+    )
+    string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" BISON_VERSION "${BISON_OUTPUT}")
+    set(BISON_MAJOR ${CMAKE_MATCH_1})
+    set(BISON_MINOR ${CMAKE_MATCH_2})
+    message(STATUS "Using bison: ${BISON_MAJOR}.${BISON_MINOR}.${CMAKE_MATCH_3}")
+    if(NOT (BISON_MAJOR GREATER_EQUAL 3 AND BISON_MINOR GREATER_EQUAL 0))
+        message(WARNING "${PORT} requires bison version greater than one provided by macOS, please use \`brew install bison\` to install a newer bison.")
+    endif()
+endif()
+
+vcpkg_find_acquire_program(BISON)
+vcpkg_find_acquire_program(FLEX)
+
+get_filename_component(FLEX_DIR "${FLEX}" DIRECTORY)
+get_filename_component(BISON_DIR "${BISON}" DIRECTORY)
+
+vcpkg_add_to_path(PREPEND "${FLEX_DIR}")
+vcpkg_add_to_path(PREPEND "${BISON_DIR}")
+
+# Prevent KDEClangFormat from writing to source effectively blocking parallel configure
+file(WRITE "${SOURCE_PATH}/.clang-format" "DisableFormat: true\nSortIncludes: false\n")
+
+# See ECM/kde-modules/KDEInstallDirs5.cmake
+# Relocate .desktop files for next ports
+if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
+    list(APPEND KDE_OPTIONS
+        -DKDE_INSTALL_KSERVICES5DIR="share/kservices5"
+        -DKDE_INSTALL_KSERVICETYPES5DIR="share/kservicetypes5"
+    )
+endif()
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        -DBUILD_TESTING=OFF
+        -DCMAKE_DISABLE_FIND_PACKAGE_KF5DocTools=ON
+        ${KDE_OPTIONS}
+)
+
+vcpkg_cmake_install()
+vcpkg_cmake_config_fixup(PACKAGE_NAME KF5Service CONFIG_PATH lib/cmake/KF5Service)
+vcpkg_copy_pdbs()
+
+vcpkg_copy_tools(
+     TOOL_NAMES kbuildsycoca5
+     AUTO_CLEAN
+)
+
+if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
+    file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/bin" "${CURRENT_PACKAGES_DIR}/debug/bin")
+endif()
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
+
+file(GLOB LICENSE_FILES "${SOURCE_PATH}/LICENSES/*")
+vcpkg_install_copyright(FILE_LIST ${LICENSE_FILES})
+