5 files changed, 219 insertions, 0 deletions
diff --git a/vcpkg/ports/libass/CMakeLists.txt b/vcpkg/ports/libass/CMakeLists.txt
new file mode 100644
index 0000000..44cd3c2
--- /dev/null
+++ b/vcpkg/ports/libass/CMakeLists.txt
@@ -0,0 +1,106 @@
+cmake_minimum_required(VERSION 3.9)
+project(libass C)
+
+include_directories(${CMAKE_CURRENT_SOURCE_DIR}/libass ${CMAKE_CURRENT_BINARY_DIR})
+
+set(CONFIG_FREETYPE 1)
+set(CONFIG_FRIBIDI 1)
+set(CONFIG_HARFBUZZ 1)
+
+file(GLOB_RECURSE SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/libass/*.c)
+
+set(PKG_REQUIRES_LIBASS "harfbuzz >= 1.2.3, fribidi >= 0.19.1, freetype2 >= 9.17.3")
+set(PKG_LIBS_LIBASS)
+if(WIN32)
+  set(CONFIG_DIRECTWRITE 1)
+  list(FILTER SOURCES EXCLUDE REGEX ".*ass_coretext.c$")
+  list(FILTER SOURCES EXCLUDE REGEX ".*ass_fontconfig.c$")
+
+  #dependency fribidi does not support uwp builds, link gdi32 directly
+  set(FONT_LIBRARY gdi32)
+  set(PKG_LIBS_LIBASS -lgdi32)
+elseif(APPLE)
+  set(CONFIG_CORETEXT 1)
+  list(FILTER SOURCES EXCLUDE REGEX ".*ass_directwrite.c$")
+  list(FILTER SOURCES EXCLUDE REGEX ".*ass_fontconfig.c$")
+
+  include(CheckCSourceCompiles)
+  check_c_source_compiles(
+    "
+    #include <ApplicationServices/ApplicationServices.h>
+    int main(void){
+      CTFontDescriptorCopyAttribute(NULL, kCTFontURLAttribute);
+      return 0;
+    }
+    "
+    CHECK_OLD_OSX
+  )
+  if(CHECK_OLD_OSX)
+    set(FONT_LIBRARY "-framework ApplicationServices -framework CoreFoundation")
+    set(PKG_LIBS_LIBASS "-framework ApplicationServices -framework CoreFoundation")
+  else()
+    set(FONT_LIBRARY "-framework CoreText -framework CoreFoundation")
+    set(PKG_LIBS_LIBASS "-framework CoreText -framework CoreFoundation")
+  endif()
+elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
+  set(CONFIG_FONTCONFIG 1)
+  list(FILTER SOURCES EXCLUDE REGEX ".*ass_coretext.c$")
+  list(FILTER SOURCES EXCLUDE REGEX ".*ass_directwrite.c$")
+
+  find_package(Fontconfig REQUIRED)
+  set(FONT_LIBRARY Fontconfig::Fontconfig)
+  set(PKG_REQUIRES_LIBASS "fontconfig >= 2.10.92, ${PKG_REQUIRES_LIBASS}")
+else()
+  list(FILTER SOURCES EXCLUDE REGEX ".*ass_directwrite.c$")
+  list(FILTER SOURCES EXCLUDE REGEX ".*ass_coretext.c$")
+  list(FILTER SOURCES EXCLUDE REGEX ".*ass_fontconfig.c$")
+endif()
+
+if(NOT WIN32)
+  set(PKG_LIBS_LIBASS "${PKG_LIBS_LIBASS} -lm")
+endif()
+
+find_package(Freetype REQUIRED)
+
+find_package(PkgConfig REQUIRED)
+pkg_check_modules(FRIBIDI REQUIRED IMPORTED_TARGET fribidi)
+pkg_check_modules(HARFBUZZ REQUIRED IMPORTED_TARGET harfbuzz)
+
+# libass use win32 api to open files on windows since https://github.com/libass/libass/commit/f664ced049394e2a5d4300ba526e206df73ec729
+# so remove dependency dirent.
+
+configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in config.h)
+
+add_library(ass ${SOURCES} ${CMAKE_CURRENT_SOURCE_DIR}/libass.def)
+
+target_include_directories(ass PRIVATE
+  PkgConfig::FRIBIDI
+  PkgConfig::HARFBUZZ)
+target_link_libraries(ass PRIVATE
+  Freetype::Freetype
+  PkgConfig::FRIBIDI
+  PkgConfig::HARFBUZZ
+  ${FONT_LIBRARY})
+
+install(TARGETS ass
+  RUNTIME DESTINATION bin
+  LIBRARY DESTINATION lib
+  ARCHIVE DESTINATION lib)
+
+# pkgconfig file
+set(prefix ${CMAKE_INSTALL_PREFIX})
+set(exec_prefix ${CMAKE_INSTALL_PREFIX})
+set(libdir ${CMAKE_INSTALL_PREFIX}/lib)
+set(includedir ${CMAKE_INSTALL_PREFIX}/include)
+set(PACKAGE_VERSION ${LIBASS_VERSION})
+if(BUILD_SHARED_LIBS)
+  set(PKG_REQUIRES_PUBLIC ${PKG_REQUIRES_LIBASS})
+  set(PKG_LIBS_PUBLIC ${PKG_LIBS_LIBASS})
+else()
+  set(PKG_REQUIRES_PRIVATE ${PKG_REQUIRES_LIBASS})
+  set(PKG_LIBS_PRIVATE ${PKG_LIBS_LIBASS})
+endif()
+configure_file(libass.pc.in libass.pc @ONLY)
+install(FILES
+        ${CMAKE_CURRENT_BINARY_DIR}/libass.pc
+        DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
diff --git a/vcpkg/ports/libass/config.h.in b/vcpkg/ports/libass/config.h.in
new file mode 100644
index 0000000..fc2445d
--- /dev/null
+++ b/vcpkg/ports/libass/config.h.in
@@ -0,0 +1,14 @@
+#define CONFIG_SOURCEVERSION "tarball: @LIBASS_VERSION@"
+
+#cmakedefine CONFIG_ICONV
+#cmakedefine CONFIG_FREETYPE
+#cmakedefine CONFIG_FRIBIDI
+#cmakedefine CONFIG_HARFBUZZ
+#cmakedefine CONFIG_LIBPNG
+#cmakedefine CONFIG_UNIBREAK
+#cmakedefine CONFIG_FONTCONFIG
+#cmakedefine CONFIG_CORETEXT
+#cmakedefine CONFIG_DIRECTWRITE
+#cmakedefine01 CONFIG_ASM
+#cmakedefine01 ARCH_X86
+#cmakedefine01 CONFIG_LARGE_TILES
diff --git a/vcpkg/ports/libass/libass.def b/vcpkg/ports/libass/libass.def
new file mode 100644
index 0000000..7edbbdf
--- /dev/null
+++ b/vcpkg/ports/libass/libass.def
@@ -0,0 +1,47 @@
+EXPORTS
+ass_library_version
+ass_library_init
+ass_library_done
+ass_set_fonts_dir
+ass_set_extract_fonts
+ass_set_style_overrides
+ass_process_force_style
+ass_set_message_cb
+ass_renderer_init
+ass_renderer_done
+ass_set_frame_size
+ass_set_storage_size
+ass_set_shaper
+ass_set_margins
+ass_set_use_margins
+ass_set_pixel_aspect
+ass_set_aspect_ratio
+ass_set_font_scale
+ass_set_hinting
+ass_set_line_spacing
+ass_set_line_position
+ass_get_available_font_providers
+ass_set_fonts
+ass_set_selective_style_override_enabled
+ass_set_selective_style_override
+ass_fonts_update
+ass_set_cache_limits
+ass_render_frame
+ass_new_track
+ass_track_set_feature
+ass_free_track
+ass_alloc_style
+ass_alloc_event
+ass_free_style
+ass_free_event
+ass_process_data
+ass_process_codec_private
+ass_process_chunk
+ass_set_check_readorder
+ass_flush_events
+ass_read_file
+ass_read_memory
+ass_read_styles
+ass_add_font
+ass_clear_fonts
+ass_step_sub
diff --git a/vcpkg/ports/libass/portfile.cmake b/vcpkg/ports/libass/portfile.cmake
new file mode 100644
index 0000000..6da6946
--- /dev/null
+++ b/vcpkg/ports/libass/portfile.cmake
@@ -0,0 +1,32 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO libass/libass
+    REF ${VERSION}
+    SHA512 08762623dd09e3034699ba9d11b70d1f6cc6b2e3b38aa897b07efef1364e76141df484e70ed27888cf3595b77d072cdb5e8abbbfa560e33ca21f87872e24df8d
+    HEAD_REF master
+)
+
+file(COPY ${CMAKE_CURRENT_LIST_DIR}/config.h.in DESTINATION ${SOURCE_PATH})
+
+file(COPY ${CMAKE_CURRENT_LIST_DIR}/libass.def DESTINATION ${SOURCE_PATH})
+
+# Since libass uses automake, make and configure, we use a custom CMake file
+file(COPY ${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt DESTINATION ${SOURCE_PATH})
+
+file(COPY ${SOURCE_PATH}/libass/ass.h ${SOURCE_PATH}/libass/ass_types.h DESTINATION ${CURRENT_PACKAGES_DIR}/include/ass)
+
+vcpkg_find_acquire_program(PKGCONFIG)
+get_filename_component(PKGCONFIG_EXE_PATH ${PKGCONFIG} DIRECTORY)
+vcpkg_add_to_path(${PKGCONFIG_EXE_PATH})
+
+vcpkg_cmake_configure(
+    OPTIONS -DLIBASS_VERSION=${VERSION}
+    SOURCE_PATH ${SOURCE_PATH}
+)
+
+vcpkg_cmake_install()
+vcpkg_copy_pdbs()
+vcpkg_fixup_pkgconfig()
+
+# Handle copyright
+file(INSTALL ${SOURCE_PATH}/COPYING DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)
diff --git a/vcpkg/ports/libass/vcpkg.json b/vcpkg/ports/libass/vcpkg.json
new file mode 100644
index 0000000..4dfa2c8
--- /dev/null
+++ b/vcpkg/ports/libass/vcpkg.json
@@ -0,0 +1,20 @@
+{
+  "name": "libass",
+  "version": "0.17.4",
+  "description": "libass is a portable subtitle renderer for the ASS/SSA (Advanced Substation Alpha/Substation Alpha) subtitle format",
+  "homepage": "https://github.com/libass/libass",
+  "license": "ISC",
+  "dependencies": [
+    {
+      "name": "fontconfig",
+      "platform": "linux"
+    },
+    "freetype",
+    "fribidi",
+    "harfbuzz",
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    }
+  ]
+}