1 files changed, 54 insertions, 0 deletions
diff --git a/vcpkg/ports/libdwarf/portfile.cmake b/vcpkg/ports/libdwarf/portfile.cmake
new file mode 100644
index 0000000..ebf70aa
--- /dev/null
+++ b/vcpkg/ports/libdwarf/portfile.cmake
@@ -0,0 +1,54 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO davea42/libdwarf-code
+    REF "v${VERSION}"
+    SHA512 9fbf58e04e49816cb1f8e34362dd7c784476422896a88042bebd09778fad4a37cbf3f4c060f491b8d55bec610be37137b24a4910498499d3fcecf9da4aa78254
+    HEAD_REF main
+    PATCHES
+        include-dir.diff # avoid dwarf.h conflict with elfutils
+        dependencies.diff
+        msvc-runtime.diff
+        dwarfdump-conf.diff # no absolute paths
+)
+
+string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "static" BUILD_NON_SHARED)
+string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "dynamic" BUILD_SHARED)
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        -DBUILD_NON_SHARED=${BUILD_NON_SHARED}
+        -DBUILD_SHARED=${BUILD_SHARED}
+    OPTIONS_DEBUG
+        -DBUILD_DWARFDUMP=OFF
+)
+
+vcpkg_cmake_install()
+vcpkg_cmake_config_fixup(CONFIG_PATH "lib/cmake/libdwarf")
+vcpkg_fixup_pkgconfig()
+vcpkg_copy_pdbs()
+vcpkg_copy_tools(TOOL_NAMES dwarfdump AUTO_CLEAN)
+
+if(BUILD_SHARED)
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/libdwarf/libdwarf.h" "ifndef LIBDWARF_STATIC" "if 1")
+endif()
+
+file(REMOVE_RECURSE
+    "${CURRENT_PACKAGES_DIR}/debug/include"
+    "${CURRENT_PACKAGES_DIR}/debug/share"
+    "${CURRENT_PACKAGES_DIR}/share/libdwarf/Findzstd.cmake"
+)
+
+file(COPY_FILE "${SOURCE_PATH}/src/lib/libdwarf/COPYING" "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/libdwarf COPYING")
+file(COPY_FILE "${SOURCE_PATH}/src/bin/dwarfdump/COPYING" "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/dwarfdump COPYING")
+file(COPY_FILE "${SOURCE_PATH}/src/bin/dwarfgen/COPYING" "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/dwarfgen COPYING")
+vcpkg_install_copyright(FILE_LIST 
+    "${SOURCE_PATH}/COPYING"
+    "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/libdwarf COPYING"
+    "${SOURCE_PATH}/src/lib/libdwarf/LIBDWARFCOPYRIGHT"
+    "${SOURCE_PATH}/src/lib/libdwarf/LGPL.txt"
+    "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/dwarfdump COPYING"
+    "${SOURCE_PATH}/src/bin/dwarfdump/DWARFDUMPCOPYRIGHT"
+    "${SOURCE_PATH}/src/bin/dwarfdump/GPL.txt"
+    "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/dwarfgen COPYING"
+)