aboutsummaryrefslogtreecommitdiff
path: root/vcpkg/ports/liblzma
diff options
context:
space:
mode:
Diffstat (limited to 'vcpkg/ports/liblzma')
-rw-r--r--vcpkg/ports/liblzma/build-tools.patch22
-rw-r--r--vcpkg/ports/liblzma/portfile.cmake86
-rw-r--r--vcpkg/ports/liblzma/usage9
-rw-r--r--vcpkg/ports/liblzma/vcpkg-cmake-wrapper.cmake64
-rw-r--r--vcpkg/ports/liblzma/vcpkg.json22
5 files changed, 203 insertions, 0 deletions
diff --git a/vcpkg/ports/liblzma/build-tools.patch b/vcpkg/ports/liblzma/build-tools.patch
new file mode 100644
index 0000000..23fd0a1
--- /dev/null
+++ b/vcpkg/ports/liblzma/build-tools.patch
@@ -0,0 +1,22 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 32506cd..0fbd454 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -1748,7 +1748,7 @@ function(my_install_man COMPONENT SRC_FILE LINK_NAMES)
+ endif()
+ endfunction()
+
+-
++if(BUILD_TOOLS)
+ #############################################################################
+ # libgnu (getopt_long)
+ #############################################################################
+@@ -2415,7 +2415,7 @@ xzdiff, xzgrep, xzmore, xzless, and their symlinks" ON)
+ src/scripts/xzless.1 "${XZLESS_LINKS}")
+ endif()
+ endif()
+-
++endif()
+
+ #############################################################################
+ # Documentation
diff --git a/vcpkg/ports/liblzma/portfile.cmake b/vcpkg/ports/liblzma/portfile.cmake
new file mode 100644
index 0000000..8cb8887
--- /dev/null
+++ b/vcpkg/ports/liblzma/portfile.cmake
@@ -0,0 +1,86 @@
+vcpkg_from_github(
+ OUT_SOURCE_PATH SOURCE_PATH
+ REPO tukaani-project/xz
+ REF "v${VERSION}"
+ SHA512 2f51fb316adb2962e0f2ef6ccc8b544cdc45087b9ad26dcd33f2025784be56578ab937c618e5826b2220b49b79b8581dcb8c6d43cd50ded7ad9de9fe61610f46
+ HEAD_REF master
+ PATCHES
+ build-tools.patch
+)
+
+vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
+ FEATURES
+ tools BUILD_TOOLS
+)
+
+if(VCPKG_TARGET_ARCHITECTURE STREQUAL "wasm32")
+ set(WASM_OPTIONS -DCMAKE_C_BYTE_ORDER=LITTLE_ENDIAN -DCMAKE_CXX_BYTE_ORDER=LITTLE_ENDIAN)
+endif()
+
+vcpkg_cmake_configure(
+ SOURCE_PATH "${SOURCE_PATH}"
+ OPTIONS
+ ${FEATURE_OPTIONS}
+ ${WASM_OPTIONS}
+ -DBUILD_TESTING=OFF
+ -DCREATE_XZ_SYMLINKS=OFF
+ -DCREATE_LZMA_SYMLINKS=OFF
+ -DCMAKE_MSVC_DEBUG_INFORMATION_FORMAT= # using flags from (vcpkg) toolchain
+ -DENABLE_NLS=OFF # nls is not supported by this port, yet
+ -DXZ_NLS=OFF
+ MAYBE_UNUSED_VARIABLES
+ CMAKE_MSVC_DEBUG_INFORMATION_FORMAT
+ CREATE_XZ_SYMLINKS
+ CREATE_LZMA_SYMLINKS
+ ENABLE_NLS
+)
+vcpkg_cmake_install()
+vcpkg_copy_pdbs()
+
+set(exec_prefix "\${prefix}")
+set(libdir "\${prefix}/lib")
+set(includedir "\${prefix}/include")
+set(PACKAGE_URL https://tukaani.org/xz/)
+set(PACKAGE_VERSION "${VERSION}")
+if(NOT VCPKG_TARGET_IS_WINDOWS)
+ set(PTHREAD_CFLAGS -pthread)
+endif()
+set(prefix "${CURRENT_INSTALLED_DIR}")
+configure_file("${SOURCE_PATH}/src/liblzma/liblzma.pc.in" "${CURRENT_PACKAGES_DIR}/lib/pkgconfig/liblzma.pc" @ONLY)
+if(NOT VCPKG_BUILD_TYPE)
+ set(prefix "${CURRENT_INSTALLED_DIR}/debug")
+ configure_file("${SOURCE_PATH}/src/liblzma/liblzma.pc.in" "${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig/liblzma.pc" @ONLY)
+endif()
+vcpkg_fixup_pkgconfig()
+
+vcpkg_cmake_config_fixup(CONFIG_PATH lib/cmake/liblzma)
+
+if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
+ vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/lzma.h" "defined(LZMA_API_STATIC)" "1")
+else()
+ vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/lzma.h" "defined(LZMA_API_STATIC)" "0")
+endif()
+
+file(REMOVE_RECURSE
+ "${CURRENT_PACKAGES_DIR}/debug/include"
+ "${CURRENT_PACKAGES_DIR}/debug/share"
+ "${CURRENT_PACKAGES_DIR}/share/man"
+)
+
+set(TOOLS xz xzdec lzmadec lzmainfo)
+foreach(_tool IN LISTS TOOLS)
+ if(NOT EXISTS "${CURRENT_PACKAGES_DIR}/bin/${_tool}${VCPKG_TARGET_EXECUTABLE_SUFFIX}")
+ list(REMOVE_ITEM TOOLS ${_tool})
+ endif()
+endforeach()
+if(TOOLS)
+ vcpkg_copy_tools(TOOL_NAMES ${TOOLS} AUTO_CLEAN)
+endif()
+
+if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
+ file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/bin" "${CURRENT_PACKAGES_DIR}/debug/bin")
+endif()
+
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/usage" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/COPYING")
diff --git a/vcpkg/ports/liblzma/usage b/vcpkg/ports/liblzma/usage
new file mode 100644
index 0000000..b1461c9
--- /dev/null
+++ b/vcpkg/ports/liblzma/usage
@@ -0,0 +1,9 @@
+liblzma is compatible with built-in CMake targets:
+
+ find_package(LibLZMA REQUIRED)
+ target_link_libraries(main PRIVATE LibLZMA::LibLZMA)
+
+liblzma provides CMake targets:
+
+ find_package(liblzma CONFIG REQUIRED)
+ target_link_libraries(main PRIVATE liblzma::liblzma)
diff --git a/vcpkg/ports/liblzma/vcpkg-cmake-wrapper.cmake b/vcpkg/ports/liblzma/vcpkg-cmake-wrapper.cmake
new file mode 100644
index 0000000..826cdba
--- /dev/null
+++ b/vcpkg/ports/liblzma/vcpkg-cmake-wrapper.cmake
@@ -0,0 +1,64 @@
+cmake_policy(PUSH)
+cmake_policy(SET CMP0012 NEW)
+cmake_policy(SET CMP0057 NEW)
+set(z_vcpkg_liblzma_fixup_needed 0)
+if(NOT "CONFIG" IN_LIST ARGS AND NOT "NO_MODULE" IN_LIST ARGS AND NOT CMAKE_DISABLE_FIND_PACKAGE_LibLZMA)
+ get_filename_component(z_vcpkg_liblzma_prefix "${CMAKE_CURRENT_LIST_DIR}" DIRECTORY)
+ get_filename_component(z_vcpkg_liblzma_prefix "${z_vcpkg_liblzma_prefix}" DIRECTORY)
+ find_path(LIBLZMA_INCLUDE_DIR NAMES lzma.h PATHS "${z_vcpkg_liblzma_prefix}/include" NO_DEFAULT_PATH)
+ # liblzma doesn't use a debug postfix, but FindLibLZMA.cmake expects it
+ find_library(LIBLZMA_LIBRARY_RELEASE NAMES lzma PATHS "${z_vcpkg_liblzma_prefix}/lib" NO_DEFAULT_PATH)
+ find_library(LIBLZMA_LIBRARY_DEBUG NAMES lzma PATHS "${z_vcpkg_liblzma_prefix}/debug/lib" NO_DEFAULT_PATH)
+ unset(z_vcpkg_liblzma_prefix)
+ if(CMAKE_VERSION VERSION_LESS 3.16)
+ # Older versions of FindLibLZMA.cmake need a single lib in LIBLZMA_LIBRARY.
+ set(z_vcpkg_liblzma_fixup_needed 1)
+ set(LIBLZMA_LIBRARY "${LIBLZMA_LIBRARY_RELEASE}" CACHE INTERNAL "")
+ elseif(NOT TARGET LibLZMA::LibLZMA)
+ set(z_vcpkg_liblzma_fixup_needed 1)
+ endif()
+ # Known values, and required. Skip expensive tests.
+ set(LIBLZMA_HAS_AUTO_DECODER 1 CACHE INTERNAL "")
+ set(LIBLZMA_HAS_EASY_ENCODER 1 CACHE INTERNAL "")
+ set(LIBLZMA_HAS_LZMA_PRESET 1 CACHE INTERNAL "")
+endif()
+
+_find_package(${ARGS})
+
+if(z_vcpkg_liblzma_fixup_needed)
+ include(SelectLibraryConfigurations)
+ select_library_configurations(LIBLZMA)
+ if(NOT TARGET LibLZMA::LibLZMA)
+ # Backfill LibLZMA::LibLZMA to versions of cmake before 3.14
+ add_library(LibLZMA::LibLZMA UNKNOWN IMPORTED)
+ if(DEFINED LIBLZMA_INCLUDE_DIRS)
+ set_target_properties(LibLZMA::LibLZMA PROPERTIES
+ INTERFACE_INCLUDE_DIRECTORIES "${LIBLZMA_INCLUDE_DIRS}")
+ endif()
+ set_property(TARGET LibLZMA::LibLZMA APPEND PROPERTY
+ IMPORTED_CONFIGURATIONS RELEASE)
+ set_target_properties(LibLZMA::LibLZMA PROPERTIES
+ IMPORTED_LINK_INTERFACE_LANGUAGES_RELEASE "C"
+ IMPORTED_LOCATION_RELEASE "${LIBLZMA_LIBRARY_RELEASE}")
+ if(EXISTS "${LIBLZMA_LIBRARY}")
+ set_target_properties(LibLZMA::LibLZMA PROPERTIES
+ IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+ IMPORTED_LOCATION "${LIBLZMA_LIBRARY}")
+ endif()
+ endif()
+ if(LIBLZMA_LIBRARY_DEBUG)
+ # Backfill debug variant to versions of cmake before 3.16
+ set_property(TARGET LibLZMA::LibLZMA APPEND PROPERTY IMPORTED_CONFIGURATIONS DEBUG)
+ set_target_properties(LibLZMA::LibLZMA PROPERTIES IMPORTED_LOCATION_DEBUG "${LIBLZMA_LIBRARY_DEBUG}")
+ endif()
+endif()
+if(LIBLZMA_LIBRARIES AND NOT "Threads::Threads" IN_LIST LIBLZMA_LIBRARIES)
+ set(THREADS_PREFER_PTHREAD_FLAG TRUE)
+ find_package(Threads)
+ list(APPEND LIBLZMA_LIBRARIES ${CMAKE_THREAD_LIBS_INIT})
+ if(TARGET LibLZMA::LibLZMA)
+ set_property(TARGET LibLZMA::LibLZMA APPEND PROPERTY INTERFACE_LINK_LIBRARIES Threads::Threads)
+ endif()
+endif()
+unset(z_vcpkg_liblzma_fixup_needed)
+cmake_policy(POP)
diff --git a/vcpkg/ports/liblzma/vcpkg.json b/vcpkg/ports/liblzma/vcpkg.json
new file mode 100644
index 0000000..ca9f89d
--- /dev/null
+++ b/vcpkg/ports/liblzma/vcpkg.json
@@ -0,0 +1,22 @@
+{
+ "name": "liblzma",
+ "version": "5.8.1",
+ "description": "Compression library with an API similar to that of zlib.",
+ "homepage": "https://tukaani.org/xz/",
+ "license": null,
+ "dependencies": [
+ {
+ "name": "vcpkg-cmake",
+ "host": true
+ },
+ {
+ "name": "vcpkg-cmake-config",
+ "host": true
+ }
+ ],
+ "features": {
+ "tools": {
+ "description": "Build tools"
+ }
+ }
+}
generated by cgit v1.2.3 (git 2.39.1) at 2026-02-15 03:39:51 +0000