1 files changed, 67 insertions, 0 deletions
diff --git a/vcpkg/ports/llama-cpp/portfile.cmake b/vcpkg/ports/llama-cpp/portfile.cmake
new file mode 100644
index 0000000..c91d8f4
--- /dev/null
+++ b/vcpkg/ports/llama-cpp/portfile.cmake
@@ -0,0 +1,67 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO ggml-org/llama.cpp
+    REF b${VERSION}
+    SHA512 c823aa1739a84b6fd50255a2c2c92e9da1cec55c62791886424b4ac126759bf9b63710e3c366fac6a004dbed0175b77756acef85ad495792142e671381b2026a
+    HEAD_REF master
+    PATCHES
+        cmake-config.diff
+        pkgconfig.diff
+)
+file(REMOVE_RECURSE "${SOURCE_PATH}/ggml/include" "${SOURCE_PATH}/ggml/src")
+
+vcpkg_check_features(OUT_FEATURE_OPTIONS options
+    FEATURES
+        download    LLAMA_CURL
+        tools       LLAMA_BUILD_TOOLS
+)
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        ${options}
+        -DGGML_CCACHE=OFF
+        -DLLAMA_ALL_WARNINGS=OFF
+        -DLLAMA_BUILD_TESTS=OFF
+        -DLLAMA_BUILD_EXAMPLES=OFF
+        -DLLAMA_BUILD_SERVER=OFF
+        -DLLAMA_USE_SYSTEM_GGML=ON
+        -DVCPKG_LOCK_FIND_PACKAGE_Git=OFF
+)
+
+vcpkg_cmake_install()
+vcpkg_cmake_config_fixup(CONFIG_PATH "lib/cmake/llama")
+vcpkg_copy_pdbs()
+vcpkg_fixup_pkgconfig()
+
+file(INSTALL "${SOURCE_PATH}/gguf-py/gguf" DESTINATION "${CURRENT_PACKAGES_DIR}/tools/${PORT}/gguf-py")
+file(RENAME "${CURRENT_PACKAGES_DIR}/bin/convert_hf_to_gguf.py" "${CURRENT_PACKAGES_DIR}/tools/${PORT}/convert-hf-to-gguf.py")
+file(REMOVE "${CURRENT_PACKAGES_DIR}/debug/bin/convert_hf_to_gguf.py")
+
+if("tools" IN_LIST FEATURES)
+    vcpkg_copy_tools(
+        TOOL_NAMES
+            llama-batched-bench
+            llama-bench
+            llama-cli
+            llama-cvector-generator
+            llama-export-lora
+            llama-gguf-split
+            llama-imatrix
+            llama-mtmd-cli
+            llama-perplexity
+            llama-quantize
+            llama-run
+            llama-tokenize
+            llama-tts
+        AUTO_CLEAN
+    )
+endif()
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
+vcpkg_clean_executables_in_bin(FILE_NAMES none)
+
+set(gguf-py-license "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/gguf-py LICENSE")
+file(COPY_FILE "${SOURCE_PATH}/gguf-py/LICENSE" "${gguf-py-license}")
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/LICENSE" "${gguf-py-license}")