1 files changed, 65 insertions, 0 deletions
diff --git a/vcpkg/ports/oniguruma/portfile.cmake b/vcpkg/ports/oniguruma/portfile.cmake
new file mode 100644
index 0000000..5cf0cdf
--- /dev/null
+++ b/vcpkg/ports/oniguruma/portfile.cmake
@@ -0,0 +1,65 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO kkos/oniguruma
+    REF "v${VERSION}"
+    SHA512 60975b876662dec8701cca5d8d4027c0a36b8effe7dd32679395ed473e26b3d6b72d7f6eb63bd4dc96c3774b594e56808ce14f993f127a5d04363232586160e4
+    HEAD_REF master
+    PATCHES 
+        fix-uwp.patch
+)
+
+vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
+    INVERTED_FEATURES
+        "non-posix" ENABLE_POSIX_API
+)
+
+if(VCPKG_CRT_LINKAGE STREQUAL "static")
+    set(MSVC_STATIC_RUNTIME ON)
+else()
+    set(MSVC_STATIC_RUNTIME OFF)
+endif()
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        ${FEATURE_OPTIONS}
+        -DMSVC_STATIC_RUNTIME=${MSVC_STATIC_RUNTIME}
+)
+
+vcpkg_cmake_install()
+
+vcpkg_copy_pdbs()
+
+vcpkg_cmake_config_fixup(CONFIG_PATH "lib/cmake/${PORT}")
+
+vcpkg_fixup_pkgconfig()
+
+# Note that onig-config is a shell script, not CMake configs, so
+# vcpkg_cmake_config_fixup would be inappropriate
+file(REMOVE "${CURRENT_PACKAGES_DIR}/bin/onig-config")
+if(EXISTS "${CURRENT_PACKAGES_DIR}/debug/bin/onig-config")
+    file(REMOVE "${CURRENT_PACKAGES_DIR}/debug/bin/onig-config")
+endif()
+
+if(VCPKG_LIBRARY_LINKAGE STREQUAL dynamic)
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/oniguruma.h"
+        "#if defined(ONIGURUMA_EXPORT)"
+        "#if 0 // defined(ONIGURUMA_EXPORT)"
+    )
+else()
+    # oniguruma.h uses `\n` as line break.
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/oniguruma.h"
+        "#ifndef ONIG_EXTERN\n#if defined(_WIN32) && !defined(__GNUC__)"
+        "#if 0\n#if defined(_WIN32) && !defined(__GNUC__)"
+    )
+endif()
+
+file(INSTALL "${SOURCE_PATH}/COPYING" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share/")
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include/")
+
+if(VCPKG_LIBRARY_LINKAGE STREQUAL "static" OR NOT VCPKG_TARGET_IS_WINDOWS)
+    file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/bin")
+    file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/bin")
+endif()