1 files changed, 82 insertions, 0 deletions
diff --git a/vcpkg/ports/onnx/portfile.cmake b/vcpkg/ports/onnx/portfile.cmake
new file mode 100644
index 0000000..f741ca0
--- /dev/null
+++ b/vcpkg/ports/onnx/portfile.cmake
@@ -0,0 +1,82 @@
+vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO onnx/onnx
+    REF "v${VERSION}"
+    SHA512 5a18e2b19ec9c18c8b115fb7e12ed98eddaa581c95f15c4dd420cd6c86e7caa04f9a393da589e76b89cf9b3544abd3749a8c77c2446782f37502eb74e9b1f661
+    PATCHES
+        fix-cmakelists.patch
+        fix-dependency-protobuf.patch
+        fix-cxx_standard.patch
+)
+
+string(COMPARE EQUAL "${VCPKG_CRT_LINKAGE}" "static" USE_STATIC_RUNTIME)
+
+# ONNX_CUSTOM_PROTOC_EXECUTABLE
+find_program(PROTOC NAMES protoc PATHS "${CURRENT_HOST_INSTALLED_DIR}/tools/protobuf" REQUIRED NO_DEFAULT_PATH NO_CMAKE_PATH)
+
+# ONNX_USE_PROTOBUF_SHARED_LIBS: find the library and check its file extension
+find_library(PROTOBUF_LIBPATH NAMES protobuf PATHS "${CURRENT_INSTALLED_DIR}/bin" "${CURRENT_INSTALLED_DIR}/lib" REQUIRED)
+get_filename_component(PROTOBUF_LIBNAME "${PROTOBUF_LIBPATH}" NAME)
+if(PROTOBUF_LIBNAME MATCHES "${CMAKE_SHARED_LIBRARY_SUFFIX}")
+    set(USE_PROTOBUF_SHARED ON)
+else()
+    set(USE_PROTOBUF_SHARED OFF)
+endif()
+
+vcpkg_find_acquire_program(PYTHON3)
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        ${FEATURE_OPTIONS}
+        "-DPython3_EXECUTABLE:FILEPATH=${PYTHON3}"
+        "-DONNX_CUSTOM_PROTOC_EXECUTABLE:FILEPATH=${PROTOC}"
+        "-DProtobuf_PROTOC_EXECUTABLE:FILEPATH=${PROTOC}"
+        -DONNX_ML=ON
+        -DONNX_USE_PROTOBUF_SHARED_LIBS=${USE_PROTOBUF_SHARED}
+        -DONNX_USE_LITE_PROTO=OFF
+        -DONNX_USE_MSVC_STATIC_RUNTIME=${USE_STATIC_RUNTIME}
+        -DONNX_BUILD_TESTS=OFF
+        -DONNX_BUILD_BENCHMARKS=OFF
+    MAYBE_UNUSED_VARIABLES
+        ONNX_USE_MSVC_STATIC_RUNTIME
+)
+vcpkg_cmake_install()
+vcpkg_cmake_config_fixup(CONFIG_PATH lib/cmake/ONNX PACKAGE_NAME ONNX)
+
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/LICENSE")
+
+file(REMOVE_RECURSE
+    "${CURRENT_PACKAGES_DIR}/debug/include"
+    "${CURRENT_PACKAGES_DIR}/debug/share"
+    # the others are empty
+    "${CURRENT_PACKAGES_DIR}/include/onnx/backend"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/bin"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/controlflow"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/generator"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/image"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/logical"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/math"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/nn"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/object_detection"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/optional"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/quantization"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/reduction"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/rnn"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/sequence"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/text"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/traditionalml"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/defs/training"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/examples"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/frontend"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/onnx_cpp2py_export"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/test"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/tools"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/onnx_ml"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/onnx_data"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/onnx_operators_ml"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/reference/ops"
+    "${CURRENT_PACKAGES_DIR}/include/onnx/reference"
+)