1 files changed, 43 insertions, 0 deletions
diff --git a/vcpkg/ports/spirv-cross/portfile.cmake b/vcpkg/ports/spirv-cross/portfile.cmake
new file mode 100644
index 0000000..6836eba
--- /dev/null
+++ b/vcpkg/ports/spirv-cross/portfile.cmake
@@ -0,0 +1,43 @@
+vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO KhronosGroup/SPIRV-Cross
+    REF vulkan-sdk-${VERSION}
+    SHA512 7b3c68fb9c2a8ff665096d03291e0339b679f80cc190b626c94a072a515a702d1bf168a6e0c618795273570a8e5c29498c041b92beb860d931f000bc8c3bb72f
+    HEAD_REF master
+)
+
+if(VCPKG_TARGET_IS_IOS)
+    message(STATUS "Using iOS triplet. Executables won't be created...")
+    set(BUILD_CLI OFF)
+else()
+    set(BUILD_CLI ON)
+endif()
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        -DSPIRV_CROSS_EXCEPTIONS_TO_ASSERTIONS=OFF
+        -DSPIRV_CROSS_CLI=${BUILD_CLI}
+        -DSPIRV_CROSS_SKIP_INSTALL=OFF
+        -DSPIRV_CROSS_ENABLE_C_API=ON
+)
+vcpkg_cmake_install()
+vcpkg_copy_pdbs()
+vcpkg_fixup_pkgconfig()
+
+foreach(COMPONENT core c cpp glsl hlsl msl reflect util)
+    vcpkg_cmake_config_fixup(CONFIG_PATH share/spirv_cross_${COMPONENT}/cmake PACKAGE_NAME spirv_cross_${COMPONENT})
+endforeach()
+
+if(BUILD_CLI)
+    vcpkg_copy_tools(TOOL_NAMES spirv-cross AUTO_CLEAN)
+endif()
+
+file(REMOVE_RECURSE
+    "${CURRENT_PACKAGES_DIR}/debug/include"
+    "${CURRENT_PACKAGES_DIR}/debug/share"
+)
+
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/LICENSE")