1 files changed, 73 insertions, 0 deletions
diff --git a/vcpkg/scripts/toolchains/osx.cmake b/vcpkg/scripts/toolchains/osx.cmake
new file mode 100644
index 0000000..8b54d4e
--- /dev/null
+++ b/vcpkg/scripts/toolchains/osx.cmake
@@ -0,0 +1,73 @@
+if(NOT _VCPKG_OSX_TOOLCHAIN)
+    set(_VCPKG_OSX_TOOLCHAIN 1)
+
+    if(POLICY CMP0056)
+        cmake_policy(SET CMP0056 NEW)
+    endif()
+    if(POLICY CMP0066)
+        cmake_policy(SET CMP0066 NEW)
+    endif()
+    if(POLICY CMP0067)
+        cmake_policy(SET CMP0067 NEW)
+    endif()
+    if(POLICY CMP0137)
+        cmake_policy(SET CMP0137 NEW)
+    endif()
+    list(APPEND CMAKE_TRY_COMPILE_PLATFORM_VARIABLES
+        VCPKG_CRT_LINKAGE VCPKG_TARGET_ARCHITECTURE
+        VCPKG_C_FLAGS VCPKG_CXX_FLAGS
+        VCPKG_C_FLAGS_DEBUG VCPKG_CXX_FLAGS_DEBUG
+        VCPKG_C_FLAGS_RELEASE VCPKG_CXX_FLAGS_RELEASE
+        VCPKG_LINKER_FLAGS VCPKG_LINKER_FLAGS_RELEASE VCPKG_LINKER_FLAGS_DEBUG
+    )
+
+    set(CMAKE_SYSTEM_NAME Darwin CACHE STRING "")
+
+    set(CMAKE_MACOSX_RPATH ON CACHE BOOL "")
+
+    if(NOT DEFINED CMAKE_SYSTEM_PROCESSOR)
+        if(VCPKG_TARGET_ARCHITECTURE STREQUAL "x64")
+           set(CMAKE_SYSTEM_PROCESSOR x86_64 CACHE STRING "")
+        elseif(VCPKG_TARGET_ARCHITECTURE STREQUAL "x86")
+           set(CMAKE_SYSTEM_PROCESSOR x86 CACHE STRING "")
+        elseif(VCPKG_TARGET_ARCHITECTURE STREQUAL "arm64")
+           set(CMAKE_SYSTEM_PROCESSOR arm64 CACHE STRING "")
+        else()
+           set(CMAKE_SYSTEM_PROCESSOR "${CMAKE_HOST_SYSTEM_PROCESSOR}" CACHE STRING "")
+        endif()
+    endif()
+
+    if(DEFINED VCPKG_CMAKE_SYSTEM_VERSION)
+        set(CMAKE_SYSTEM_VERSION "${VCPKG_CMAKE_SYSTEM_VERSION}" CACHE STRING "" FORCE)
+    endif()
+
+    if(CMAKE_HOST_SYSTEM_NAME STREQUAL "Darwin")
+        if(CMAKE_SYSTEM_PROCESSOR STREQUAL CMAKE_HOST_SYSTEM_PROCESSOR)
+            set(CMAKE_CROSSCOMPILING OFF CACHE STRING "")
+        elseif(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL "arm64")
+            # arm64 macOS can run x64 binaries
+            set(CMAKE_CROSSCOMPILING OFF CACHE STRING "")
+        endif()
+
+        if(NOT DEFINED CMAKE_SYSTEM_VERSION)
+            set(CMAKE_SYSTEM_VERSION "${CMAKE_HOST_SYSTEM_VERSION}" CACHE STRING "")
+        endif()
+    endif()
+
+    string(APPEND CMAKE_C_FLAGS_INIT " -fPIC ${VCPKG_C_FLAGS} ")
+    string(APPEND CMAKE_CXX_FLAGS_INIT " -fPIC ${VCPKG_CXX_FLAGS} ")
+    string(APPEND CMAKE_C_FLAGS_DEBUG_INIT " ${VCPKG_C_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_CXX_FLAGS_DEBUG_INIT " ${VCPKG_CXX_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_C_FLAGS_RELEASE_INIT " ${VCPKG_C_FLAGS_RELEASE} ")
+    string(APPEND CMAKE_CXX_FLAGS_RELEASE_INIT " ${VCPKG_CXX_FLAGS_RELEASE} ")
+
+    string(APPEND CMAKE_MODULE_LINKER_FLAGS_INIT " ${VCPKG_LINKER_FLAGS} ")
+    string(APPEND CMAKE_SHARED_LINKER_FLAGS_INIT " ${VCPKG_LINKER_FLAGS} ")
+    string(APPEND CMAKE_EXE_LINKER_FLAGS_INIT " ${VCPKG_LINKER_FLAGS} ")
+    string(APPEND CMAKE_MODULE_LINKER_FLAGS_DEBUG_INIT " ${VCPKG_LINKER_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_SHARED_LINKER_FLAGS_DEBUG_INIT " ${VCPKG_LINKER_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_EXE_LINKER_FLAGS_DEBUG_INIT " ${VCPKG_LINKER_FLAGS_DEBUG} ")
+    string(APPEND CMAKE_MODULE_LINKER_FLAGS_RELEASE_INIT " ${VCPKG_LINKER_FLAGS_RELEASE} ")
+    string(APPEND CMAKE_SHARED_LINKER_FLAGS_RELEASE_INIT " ${VCPKG_LINKER_FLAGS_RELEASE} ")
+    string(APPEND CMAKE_EXE_LINKER_FLAGS_RELEASE_INIT " ${VCPKG_LINKER_FLAGS_RELEASE} ")
+endif()