blob: 8358e27a9c1961656b5953efdb0e598b458d2918 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
cmake_minimum_required(VERSION 3.5)
project(EDFlib LANGUAGES C)
option(BUILD_TOOLS "Build EDFlib tools." OFF)
include(GNUInstallDirs)
set(sources edflib.h edflib.c)
add_library(EDFlib ${sources})
if(BUILD_SHARED_LIBS)
target_compile_definitions(EDFlib
PUBLIC
EDFLIB_SO_DLL
PRIVATE
$<BUILD_INTERFACE:EDFLIB_BUILD>
)
endif()
if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
target_compile_definitions(EDFlib PRIVATE _LARGEFILE64_SOURCE _LARGEFILE_SOURCE)
target_compile_options(EDFlib PRIVATE -Wall -Wextra -Wshadow -Wformat-nonliteral -Wformat-security)
endif()
set_target_properties(EDFlib PROPERTIES PUBLIC_HEADER edflib.h)
install(TARGETS EDFlib
EXPORT EDFlibTargets
PUBLIC_HEADER DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
INCLUDES DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
)
install(EXPORT EDFlibTargets
FILE unofficial-EDFlibConfig.cmake
DESTINATION "share/unofficial-EDFlib"
)
if(BUILD_TOOLS)
include(CheckSymbolExists)
# https://stackoverflow.com/questions/32816646/can-cmake-detect-if-i-need-to-link-to-libm-when-using-pow-in-c
if(NOT POW_FUNCTION_EXISTS AND NOT NEED_LINKING_AGAINST_LIBM)
check_symbol_exists(pow "math.h" POW_FUNCTION_EXISTS)
if(NOT POW_FUNCTION_EXISTS)
unset(POW_FUNCTION_EXISTS CACHE)
list(APPEND CMAKE_REQUIRED_LIBRARIES m)
check_symbol_exists(pow "math.h" POW_FUNCTION_EXISTS)
if(POW_FUNCTION_EXISTS)
set(NEED_LINKING_AGAINST_LIBM True CACHE BOOL "" FORCE)
else()
message(FATAL_ERROR "Failed making the pow() function available")
endif()
endif()
endif()
add_executable(sine_generator sine_generator.c)
target_link_libraries(sine_generator PRIVATE EDFlib)
add_executable(sweep_generator sweep_generator.c)
target_link_libraries(sweep_generator PRIVATE EDFlib)
if(NEED_LINKING_AGAINST_LIBM)
target_link_libraries(sine_generator PRIVATE m)
target_link_libraries(sweep_generator PRIVATE m)
endif()
install(TARGETS sine_generator sweep_generator
RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
)
endif()
|
